vasilito
068a1ca63e
Bootloader fork rebase:
- Base changed from 0.1.0 pre-patched archive to upstream 1.0.0 tag (c7eeb9f)
- Applied 0001-redbear-local-forks.patch (Cargo.toml crate path redirects)
- Applied fix-uefi-alloc-panic.patch equivalents (4 panic!() -> graceful
error handling in src/main.rs)
- Applied P5-live-preload-cap-1gib.patch (1 GiB cap on live image preload)
- Skipped: P0 GPT partition scan (requires new module + integration),
P1 timeout/default-resolution, P2 live preload guard (subsumed by
panic fixes + cap), P3 live image safe read, P4 large ISO boot,
redox.patch — to be applied in dedicated rebase session.
firmware-loader/Cargo.toml: version 0.1.0 -> 0.3.0 (sync with other
Red Bear custom crates which are at 0.3.0).
fork-upstream-map.toml: bootloader back from PENDING_REBASE to 1.0.0
since the partial rebase matches upstream 1.0.0 content.
fork-upstream-map.toml: base restored to 'main' tracked (was correctly
tracked by build-redbear.sh).
58 lines
1.8 KiB
Plaintext
58 lines
1.8 KiB
Plaintext
# limits-h.m4
|
|
# serial 1
|
|
dnl Copyright 2016-2025 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
dnl This file is offered as-is, without any warranty.
|
|
|
|
dnl Check whether limits.h has needed features.
|
|
|
|
dnl From Paul Eggert.
|
|
|
|
AC_DEFUN_ONCE([gl_LIMITS_H],
|
|
[
|
|
gl_CHECK_NEXT_HEADERS([limits.h])
|
|
|
|
AC_CACHE_CHECK([whether limits.h has WORD_BIT, BOOL_WIDTH etc.],
|
|
[gl_cv_header_limits_width],
|
|
[AC_COMPILE_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[#ifndef __STDC_WANT_IEC_60559_BFP_EXT__
|
|
#define __STDC_WANT_IEC_60559_BFP_EXT__ 1
|
|
#endif
|
|
#include <limits.h>
|
|
long long llm = LLONG_MAX;
|
|
int wb = WORD_BIT;
|
|
int ullw = ULLONG_WIDTH;
|
|
int bw = BOOL_WIDTH;
|
|
int bm = BOOL_MAX;
|
|
int mblm = MB_LEN_MAX;
|
|
]])],
|
|
[gl_cv_header_limits_width=yes],
|
|
[gl_cv_header_limits_width=no])])
|
|
GL_GENERATE_LIMITS_H=true
|
|
AS_IF([test "$gl_cv_header_limits_width" = yes],
|
|
[AC_CACHE_CHECK([whether limits.h has SSIZE_MAX],
|
|
[gl_cv_header_limits_ssize_max],
|
|
[AC_COMPILE_IFELSE(
|
|
[AC_LANG_SOURCE(
|
|
[[#include <limits.h>
|
|
#ifndef SSIZE_MAX
|
|
#error "SSIZE_MAX is not defined"
|
|
#endif
|
|
]])],
|
|
[gl_cv_header_limits_ssize_max=yes],
|
|
[gl_cv_header_limits_ssize_max=no])])
|
|
if test "$gl_cv_header_limits_ssize_max" = yes; then
|
|
GL_GENERATE_LIMITS_H=false
|
|
fi])
|
|
])
|
|
|
|
dnl Unconditionally enables the replacement of <limits.h>.
|
|
AC_DEFUN([gl_REPLACE_LIMITS_H],
|
|
[
|
|
AC_REQUIRE([gl_LIMITS_H])
|
|
GL_GENERATE_LIMITS_H=true
|
|
])
|