vasilito
068a1ca63e
Bootloader fork rebase:
- Base changed from 0.1.0 pre-patched archive to upstream 1.0.0 tag (c7eeb9f)
- Applied 0001-redbear-local-forks.patch (Cargo.toml crate path redirects)
- Applied fix-uefi-alloc-panic.patch equivalents (4 panic!() -> graceful
error handling in src/main.rs)
- Applied P5-live-preload-cap-1gib.patch (1 GiB cap on live image preload)
- Skipped: P0 GPT partition scan (requires new module + integration),
P1 timeout/default-resolution, P2 live preload guard (subsumed by
panic fixes + cap), P3 live image safe read, P4 large ISO boot,
redox.patch — to be applied in dedicated rebase session.
firmware-loader/Cargo.toml: version 0.1.0 -> 0.3.0 (sync with other
Red Bear custom crates which are at 0.3.0).
fork-upstream-map.toml: bootloader back from PENDING_REBASE to 1.0.0
since the partial rebase matches upstream 1.0.0 content.
fork-upstream-map.toml: base restored to 'main' tracked (was correctly
tracked by build-redbear.sh).
71 lines
2.3 KiB
Plaintext
71 lines
2.3 KiB
Plaintext
# gettime.m4
|
|
# serial 15
|
|
dnl Copyright (C) 2002, 2004-2006, 2009-2025 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
dnl This file is offered as-is, without any warranty.
|
|
|
|
AC_DEFUN([gl_GETTIME],
|
|
[
|
|
dnl Prerequisites of lib/gettime.c.
|
|
AC_REQUIRE([gl_CLOCK_TIME])
|
|
AC_REQUIRE([gl_TIMESPEC])
|
|
|
|
AC_REQUIRE([gl_CHECK_FUNC_TIMESPEC_GET])
|
|
if test $gl_cv_func_timespec_get = yes; then
|
|
AC_DEFINE([HAVE_TIMESPEC_GET], [1],
|
|
[Define if you have the timespec_get function.])
|
|
fi
|
|
])
|
|
|
|
dnl Tests whether the function timespec_get exists.
|
|
dnl Sets gl_cv_func_timespec_get and gl_cv_onwards_func_timespec_get.
|
|
AC_DEFUN([gl_CHECK_FUNC_TIMESPEC_GET],
|
|
[
|
|
AC_REQUIRE([AC_CANONICAL_HOST])
|
|
|
|
dnl Persuade OpenBSD <time.h> to declare timespec_get().
|
|
AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
|
|
|
|
dnl We can't use AC_CHECK_FUNC here, because timespec_get() is defined as a
|
|
dnl static inline function in <time.h> on MSVC 14.
|
|
dnl But at the same time, we need to notice a missing declaration, like
|
|
dnl gl_CHECK_FUNCS_ANDROID does.
|
|
AC_CHECK_DECL([timespec_get], , , [[#include <time.h>]])
|
|
AC_CACHE_CHECK([for timespec_get], [gl_cv_onwards_func_timespec_get],
|
|
[if test $ac_cv_have_decl_timespec_get = yes; then
|
|
AC_LINK_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[#include <time.h>
|
|
struct timespec ts;
|
|
]],
|
|
[[return timespec_get (&ts, 0);]])
|
|
],
|
|
[gl_cv_onwards_func_timespec_get=yes],
|
|
[gl_cv_onwards_func_timespec_get=no])
|
|
else
|
|
gl_cv_onwards_func_timespec_get=no
|
|
fi
|
|
case "$host_os" in
|
|
linux*-android*)
|
|
if test $gl_cv_onwards_func_timespec_get = no; then
|
|
gl_cv_onwards_func_timespec_get='future OS version'
|
|
fi
|
|
;;
|
|
esac
|
|
])
|
|
case "$gl_cv_onwards_func_timespec_get" in
|
|
future*) gl_cv_func_timespec_get=no ;;
|
|
*) gl_cv_func_timespec_get=$gl_cv_onwards_func_timespec_get ;;
|
|
esac
|
|
])
|
|
|
|
AC_DEFUN([gl_GETTIME_RES],
|
|
[
|
|
dnl Prerequisites of lib/gettime-res.c.
|
|
AC_REQUIRE([gl_CLOCK_TIME])
|
|
AC_REQUIRE([gl_TIMESPEC])
|
|
gl_CHECK_FUNCS_ANDROID([timespec_getres], [[#include <time.h>]])
|
|
])
|