vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
59 lines
1.9 KiB
CMake
59 lines
1.9 KiB
CMake
# Copyright (C) 2022 The Qt Company Ltd.
|
|
# SPDX-License-Identifier: BSD-3-Clause
|
|
|
|
find_package(PkgConfig QUIET)
|
|
pkg_check_modules(PC_GSSAPI QUIET "krb5-gssapi")
|
|
if (NOT PC_GSSAPI_FOUND)
|
|
pkg_check_modules(PC_GSSAPI QUIET "mit-krb5-gssapi")
|
|
endif()
|
|
|
|
find_path(GSSAPI_INCLUDE_DIRS
|
|
NAMES gssapi/gssapi.h
|
|
HINTS ${PC_GSSAPI_INCLUDEDIR}
|
|
)
|
|
|
|
# On macOS, vcpkg opts for finding frameworks LAST. This is generally fine;
|
|
# however, in the case of GSSAPI, `usr/lib/libgssapi_krb5.tbd` which is a
|
|
# symlink to `Kerberos.framework` misses a few symols, e.g.,
|
|
# `___gss_c_nt_hostbased_service_oid_desc`, and it causes build failure.
|
|
# So, we need to make sure that we find `GSS.framework`.
|
|
set(gssapi_library_names
|
|
GSS # framework
|
|
gss # solaris
|
|
gssapi # FreeBSD
|
|
gssapi_krb5
|
|
)
|
|
if(APPLE)
|
|
list(REMOVE_ITEM gssapi_library_names "gssapi_krb5")
|
|
endif()
|
|
|
|
find_library(GSSAPI_LIBRARIES
|
|
NAMES
|
|
${gssapi_library_names}
|
|
HINTS ${PC_GSSAPI_LIBDIR}
|
|
)
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(GSSAPI DEFAULT_MSG GSSAPI_LIBRARIES GSSAPI_INCLUDE_DIRS)
|
|
|
|
if(GSSAPI_FOUND AND NOT TARGET GSSAPI::GSSAPI)
|
|
if(GSSAPI_LIBRARIES MATCHES "/([^/]+)\\.framework$")
|
|
add_library(GSSAPI::GSSAPI INTERFACE IMPORTED)
|
|
set_target_properties(GSSAPI::GSSAPI PROPERTIES
|
|
INTERFACE_LINK_LIBRARIES "${GSSAPI_LIBRARIES}")
|
|
else()
|
|
add_library(GSSAPI::GSSAPI UNKNOWN IMPORTED)
|
|
set_target_properties(GSSAPI::GSSAPI PROPERTIES
|
|
IMPORTED_LOCATION "${GSSAPI_LIBRARIES}")
|
|
endif()
|
|
|
|
set_target_properties(GSSAPI::GSSAPI PROPERTIES
|
|
INTERFACE_INCLUDE_DIRECTORIES "${GSSAPI_INCLUDE_DIRS}")
|
|
endif()
|
|
|
|
mark_as_advanced(GSSAPI_INCLUDE_DIRS GSSAPI_LIBRARIES)
|
|
|
|
include(FeatureSummary)
|
|
set_package_properties(GSSAPI PROPERTIES
|
|
DESCRIPTION "Generic Security Services Application Program Interface")
|