vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
54 lines
3.0 KiB
Plaintext
54 lines
3.0 KiB
Plaintext
# Special version of WAYLANDCLIENTSOURCES to be used with protocols that
|
|
# have requests that create objects with interfaces defined in the core
|
|
# wayland protocol.
|
|
#
|
|
# E.g. if a protocol has a request which creates a wl_buffer. With
|
|
# the regular wayland-scanner.prf compilation would fail because
|
|
# wl_buffer_interface is not defined.
|
|
#
|
|
# This version solves the problem by prepending
|
|
# #include <QtWaylandClient/private/wayland-wayland-client-protocol.h>
|
|
# to the wayland-scanner generated files.
|
|
|
|
isEmpty(QMAKE_WAYLAND_SCANNER):error("QMAKE_WAYLAND_SCANNER not defined for this mkspec")
|
|
|
|
!isEmpty(MODULE_INCNAME) {
|
|
WAYLAND_INCLUDE_DIR = $$MODULE_INCNAME/private
|
|
}
|
|
|
|
wayland_client_header.name = wayland ${QMAKE_FILE_BASE}
|
|
wayland_client_header.input = WAYLANDCLIENTSOURCES
|
|
wayland_client_header.variable_out = HEADERS
|
|
wayland_client_header.output = wayland-${QMAKE_FILE_BASE}-client-protocol$${first(QMAKE_EXT_H)}
|
|
# XXX: Prepend the necessary include in the generated header
|
|
wayland_client_header.commands = echo \"$${LITERAL_HASH}include <QtWaylandClient/private/wayland-wayland-client-protocol.h>\" > ${QMAKE_FILE_OUT} && $$QMAKE_WAYLAND_SCANNER --include-core-only client-header < ${QMAKE_FILE_IN} >> ${QMAKE_FILE_OUT}
|
|
QMAKE_EXTRA_COMPILERS += wayland_client_header
|
|
|
|
wayland_code.name = wayland ${QMAKE_FILE_BASE}
|
|
wayland_code.input = WAYLANDCLIENTSOURCES
|
|
wayland_code.variable_out = SOURCES
|
|
wayland_code.output = wayland-${QMAKE_FILE_BASE}-protocol.c
|
|
wayland_code.commands = $$QMAKE_WAYLAND_SCANNER --include-core-only code < ${QMAKE_FILE_IN} > ${QMAKE_FILE_OUT}
|
|
silent:wayland_code.commands = @echo Wayland code header ${QMAKE_FILE_IN} && $$wayland_code.commands
|
|
QMAKE_EXTRA_COMPILERS += wayland_code
|
|
|
|
qtPrepareTool(QMAKE_QTWAYLANDSCANNER, qtwaylandscanner)
|
|
|
|
qtwayland_client_header.name = qtwayland ${QMAKE_FILE_BASE}
|
|
qtwayland_client_header.input = WAYLANDCLIENTSOURCES
|
|
qtwayland_client_header.variable_out = HEADERS
|
|
qtwayland_client_header.depends += $$QMAKE_QTWAYLANDSCANNER_EXE wayland-${QMAKE_FILE_BASE}-client-protocol$${first(QMAKE_EXT_H)}
|
|
qtwayland_client_header.output = qwayland-${QMAKE_FILE_BASE}$${first(QMAKE_EXT_H)}
|
|
qtwayland_client_header.commands = $$QMAKE_QTWAYLANDSCANNER client-header ${QMAKE_FILE_IN} $$WAYLAND_INCLUDE_DIR > ${QMAKE_FILE_OUT}
|
|
silent:qtwayland_client_header.commands = @echo QtWayland client header ${QMAKE_FILE_IN} && $$qtwayland_client_header.commands
|
|
QMAKE_EXTRA_COMPILERS += qtwayland_client_header
|
|
|
|
qtwayland_client_code.name = qtwayland ${QMAKE_FILE_BASE}
|
|
qtwayland_client_code.input = WAYLANDCLIENTSOURCES
|
|
qtwayland_client_code.variable_out = SOURCES
|
|
qtwayland_client_code.depends += $$QMAKE_QTWAYLANDSCANNER_EXE qwayland-${QMAKE_FILE_BASE}$${first(QMAKE_EXT_H)}
|
|
qtwayland_client_code.output = qwayland-${QMAKE_FILE_BASE}.cpp
|
|
qtwayland_client_code.commands = $$QMAKE_QTWAYLANDSCANNER client-code ${QMAKE_FILE_IN} $$WAYLAND_INCLUDE_DIR > ${QMAKE_FILE_OUT}
|
|
silent:qtwayland_client_code.commands = @echo QtWayland client code ${QMAKE_FILE_IN} && $$qtwayland_client_code.commands
|
|
QMAKE_EXTRA_COMPILERS += qtwayland_client_code
|