vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
76 lines
3.4 KiB
CMake
76 lines
3.4 KiB
CMake
# Copyright (C) 2022 The Qt Company Ltd.
|
|
# SPDX-License-Identifier: BSD-3-Clause
|
|
|
|
# We can't create the same interface imported target multiple times, CMake will complain if we do
|
|
# that. This can happen if the find_package call is done in multiple different subdirectories.
|
|
if(TARGET WrapVulkanHeaders::WrapVulkanHeaders)
|
|
set(WrapVulkanHeaders_FOUND ON)
|
|
return()
|
|
endif()
|
|
|
|
set(WrapVulkanHeaders_FOUND OFF)
|
|
|
|
find_package(Vulkan ${WrapVulkanHeaders_FIND_VERSION} QUIET)
|
|
|
|
# We are interested only in include headers. The libraries might be missing, so we can't check the
|
|
# _FOUND variable.
|
|
if(Vulkan_INCLUDE_DIR)
|
|
set(WrapVulkanHeaders_FOUND ON)
|
|
|
|
add_library(WrapVulkanHeaders::WrapVulkanHeaders INTERFACE IMPORTED)
|
|
target_include_directories(WrapVulkanHeaders::WrapVulkanHeaders INTERFACE
|
|
${Vulkan_INCLUDE_DIR})
|
|
|
|
set_target_properties(WrapVulkanHeaders::WrapVulkanHeaders PROPERTIES
|
|
_qt_is_nolink_target TRUE)
|
|
|
|
set_target_properties(WrapVulkanHeaders::WrapVulkanHeaders PROPERTIES
|
|
_qt_skip_include_dir_for_pri TRUE)
|
|
|
|
# Also propagate MoltenVK include directory on Apple platforms if found.
|
|
if(APPLE)
|
|
# Check for the LunarG Vulkan SDK folder structure.
|
|
set(__qt_molten_vk_include_path "${Vulkan_INCLUDE_DIR}/../../MoltenVK/include")
|
|
get_filename_component(
|
|
__qt_molten_vk_include_path
|
|
"${__qt_molten_vk_include_path}" ABSOLUTE)
|
|
if(EXISTS "${__qt_molten_vk_include_path}")
|
|
target_include_directories(WrapVulkanHeaders::WrapVulkanHeaders INTERFACE
|
|
${__qt_molten_vk_include_path})
|
|
endif()
|
|
|
|
# Check for homebrew molten-vk folder structure
|
|
set(__qt_molten_vk_homebrew_include_path "${Vulkan_INCLUDE_DIR}/../../include")
|
|
get_filename_component(
|
|
__qt_molten_vk_homebrew_include_path
|
|
"${__qt_molten_vk_homebrew_include_path}" ABSOLUTE)
|
|
if(EXISTS "${__qt_molten_vk_homebrew_include_path}")
|
|
target_include_directories(WrapVulkanHeaders::WrapVulkanHeaders INTERFACE
|
|
${__qt_molten_vk_homebrew_include_path})
|
|
endif()
|
|
|
|
# Check for homebrew vulkan-headers folder structure
|
|
# If instead of molten-vk folder, CMAKE_PREFIX_PATH points to Homebrew's
|
|
# vulkan-headers installation, then we will not be able to find molten-vk
|
|
# headers. If we assume that user has installed the molten-vk formula as
|
|
# well, then we might have a chance to pick it up like this.
|
|
if(Vulkan_INCLUDE_DIR MATCHES "/homebrew/Cellar/")
|
|
set(__qt_standalone_molten_vk_homebrew_include_path
|
|
"${Vulkan_INCLUDE_DIR}/../../../../opt/molten-vk/include")
|
|
else()
|
|
set(__qt_standalone_molten_vk_homebrew_include_path
|
|
"${Vulkan_INCLUDE_DIR}/../../molten-vk/include")
|
|
endif()
|
|
get_filename_component(
|
|
__qt_standalone_molten_vk_homebrew_include_path
|
|
"${__qt_standalone_molten_vk_homebrew_include_path}" ABSOLUTE)
|
|
if(EXISTS "${__qt_standalone_molten_vk_homebrew_include_path}")
|
|
target_include_directories(WrapVulkanHeaders::WrapVulkanHeaders INTERFACE
|
|
${__qt_standalone_molten_vk_homebrew_include_path})
|
|
endif()
|
|
endif()
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(WrapVulkanHeaders DEFAULT_MSG Vulkan_INCLUDE_DIR)
|