vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
72 lines
1.7 KiB
CMake
72 lines
1.7 KiB
CMake
# Copyright (C) 2022 The Qt Company Ltd.
|
|
# SPDX-License-Identifier: BSD-3-Clause
|
|
|
|
#.rst:
|
|
# FindDB2
|
|
# ---------
|
|
#
|
|
# Try to locate the db2 client library.
|
|
# If found, this will define the following variables:
|
|
#
|
|
# ``DB2_FOUND``
|
|
# True if the db2 library is available
|
|
# ``DB2_INCLUDE_DIRS``
|
|
# The db2 include directories
|
|
# ``DB2_LIBRARIES``
|
|
# The db2 libraries for linking
|
|
#
|
|
# If ``DB2_FOUND`` is TRUE, it will also define the following
|
|
# imported target:
|
|
#
|
|
# ``DB2::DB2``
|
|
# The db2 client library
|
|
|
|
if(NOT DEFINED DB2_ROOT)
|
|
if(DEFINED ENV{DB2_ROOT})
|
|
set(DB2_ROOT "$ENV{DB2_ROOT}")
|
|
endif()
|
|
endif()
|
|
|
|
if (NOT DEFINED DB2_INCLUDE_DIR)
|
|
find_path(DB2_INCLUDE_DIR
|
|
NAMES sqlcli1.h
|
|
HINTS "${DB2_ROOT}" ENV DB2_HOME
|
|
PATH_SUFFIXES include)
|
|
else()
|
|
find_path(DB2_INCLUDE_DIR
|
|
NAMES sqlcli1.h
|
|
HINTS "${DB2_INCLUDE_DIR}")
|
|
endif()
|
|
|
|
if (NOT DEFINED DB2_LIBRARY_DIR)
|
|
find_library(DB2_LIBRARY
|
|
NAMES db2 db2cli64
|
|
HINTS "${DB2_ROOT}" ENV DB2LIB)
|
|
else()
|
|
find_library(DB2_LIBRARY
|
|
NAMES db2
|
|
HINTS "${DB2_LIBRARY_DIR}")
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(DB2 DEFAULT_MSG DB2_INCLUDE_DIR DB2_LIBRARY)
|
|
|
|
if(DB2_FOUND)
|
|
set(DB2_INCLUDE_DIRS "${DB2_INCLUDE_DIR}")
|
|
set(DB2_LIBRARIES "${DB2_LIBRARY}")
|
|
if(NOT TARGET DB2::DB2)
|
|
add_library(DB2::DB2 UNKNOWN IMPORTED)
|
|
set_target_properties(DB2::DB2 PROPERTIES
|
|
IMPORTED_LOCATION "${DB2_LIBRARIES}"
|
|
INTERFACE_INCLUDE_DIRECTORIES "${DB2_INCLUDE_DIRS}")
|
|
endif()
|
|
endif()
|
|
|
|
mark_as_advanced(DB2_INCLUDE_DIR DB2_LIBRARY)
|
|
|
|
include(FeatureSummary)
|
|
set_package_properties(DB2 PROPERTIES
|
|
URL "https://www.ibm.com"
|
|
DESCRIPTION "IBM DB2 client library")
|
|
|