vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
85 lines
2.3 KiB
QML
85 lines
2.3 KiB
QML
// Copyright (C) 2024 The Qt Company Ltd.
|
|
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR GPL-3.0-only
|
|
|
|
import QtQuick
|
|
import QtQuick.Controls
|
|
|
|
Rectangle {
|
|
width: 400
|
|
height: 400
|
|
color: palette.window
|
|
|
|
Row {
|
|
CheckBox {
|
|
id: smoothCB
|
|
text: "smooth"
|
|
}
|
|
CheckBox {
|
|
id: aaCB
|
|
text: "antialiasing"
|
|
checked: true
|
|
}
|
|
CheckBox {
|
|
id: angleCB
|
|
text: "by angle"
|
|
}
|
|
}
|
|
|
|
Rectangle {
|
|
color: "orange"
|
|
width: 300; height: 200
|
|
anchors.centerIn: parent
|
|
transform: Shear {
|
|
id: barber
|
|
origin.x: 150
|
|
origin.y: 100
|
|
xAngle: angleCB.checked ? hwheel.rotation : 0
|
|
yAngle: angleCB.checked ? vwheel.rotation : 0
|
|
xFactor: !angleCB.checked ? hwheel.rotation / 120 : 0
|
|
yFactor: !angleCB.checked ? vwheel.rotation / 120 : 0
|
|
}
|
|
smooth: smoothCB.checked
|
|
antialiasing: aaCB.checked
|
|
|
|
Text {
|
|
text: "use mouse wheels / touchpad gestures to shear\nclick to set shear center"
|
|
horizontalAlignment: Text.AlignHCenter
|
|
anchors.centerIn: parent
|
|
}
|
|
|
|
Rectangle {
|
|
x: barber.origin.x - width / 2
|
|
y: barber.origin.y - width / 2
|
|
width: 5; height: 5; radius: 2.5
|
|
color: "red"
|
|
}
|
|
|
|
WheelHandler {
|
|
id: vwheel
|
|
acceptedDevices: PointerDevice.Mouse | PointerDevice.TouchPad
|
|
target: null
|
|
}
|
|
|
|
WheelHandler {
|
|
id: hwheel
|
|
acceptedDevices: PointerDevice.Mouse | PointerDevice.TouchPad
|
|
orientation: Qt.Horizontal
|
|
target: null
|
|
}
|
|
|
|
TapHandler {
|
|
onTapped: barber.origin = point.position
|
|
}
|
|
}
|
|
|
|
Text {
|
|
color: palette.windowText
|
|
text: angleCB.checked ?
|
|
"angles " + barber.xAngle.toFixed(3) + ", " + barber.yAngle.toFixed(3)
|
|
+ "\ntangents " + Math.tan(barber.xAngle * Math.PI / 180).toFixed(2) + ", "
|
|
+ Math.tan(barber.yAngle * Math.PI / 180).toFixed(2)
|
|
: "factors " + barber.xFactor.toFixed(3) + ", " + barber.yFactor.toFixed(3)
|
|
anchors.bottom: parent.bottom
|
|
}
|
|
}
|