vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
102 lines
3.4 KiB
CMake
102 lines
3.4 KiB
CMake
# Copyright (C) 2022 The Qt Company Ltd.
|
|
# SPDX-License-Identifier: BSD-3-Clause
|
|
|
|
#.rst:
|
|
# FindZstd
|
|
# ---------
|
|
#
|
|
# Try to locate the Zstd library.
|
|
# If found, this will define the following variables:
|
|
#
|
|
# ``WrapZSTD_FOUND``
|
|
# True if the zstd library is available
|
|
# ``ZSTD_INCLUDE_DIRS``
|
|
# The zstd include directories
|
|
# ``ZSTD_LIBRARIES``
|
|
# The zstd libraries for linking
|
|
#
|
|
# If ``WrapZSTD_FOUND`` is TRUE, it will also define the following
|
|
# imported target:
|
|
#
|
|
# ``WrapZSTD::WrapZSTD``
|
|
# The zstd library
|
|
|
|
find_package(zstd CONFIG QUIET)
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
|
|
if(TARGET zstd::libzstd_static OR TARGET zstd::libzstd_shared OR TARGET zstd::libzstd)
|
|
find_package_handle_standard_args(WrapZSTD
|
|
REQUIRED_VARS zstd_VERSION VERSION_VAR zstd_VERSION)
|
|
if(TARGET zstd::libzstd_shared)
|
|
set(zstdtargetsuffix "_shared")
|
|
elseif(TARGET zstd::libzstd)
|
|
set(zstdtargetsuffix "")
|
|
else()
|
|
set(zstdtargetsuffix "_static")
|
|
endif()
|
|
|
|
if(NOT TARGET WrapZSTD::WrapZSTD)
|
|
add_library(WrapZSTD::WrapZSTD INTERFACE IMPORTED)
|
|
set_target_properties(WrapZSTD::WrapZSTD PROPERTIES
|
|
INTERFACE_LINK_LIBRARIES "zstd::libzstd${zstdtargetsuffix}")
|
|
endif()
|
|
else()
|
|
get_cmake_property(__packages_not_found PACKAGES_NOT_FOUND)
|
|
if(__packages_not_found)
|
|
list(REMOVE_ITEM __packages_not_found zstd)
|
|
set_property(GLOBAL PROPERTY PACKAGES_NOT_FOUND "${__packages_not_found}")
|
|
endif()
|
|
unset(__packages_not_found)
|
|
|
|
find_package(PkgConfig QUIET)
|
|
pkg_check_modules(PC_ZSTD QUIET "libzstd")
|
|
|
|
find_path(ZSTD_INCLUDE_DIRS
|
|
NAMES zstd.h
|
|
HINTS ${PC_ZSTD_INCLUDEDIR}
|
|
PATH_SUFFIXES zstd)
|
|
|
|
find_library(ZSTD_LIBRARY_RELEASE
|
|
NAMES zstd zstd_static
|
|
HINTS ${PC_ZSTD_LIBDIR}
|
|
)
|
|
find_library(ZSTD_LIBRARY_DEBUG
|
|
NAMES zstdd zstd_staticd zstd zstd_static
|
|
HINTS ${PC_ZSTD_LIBDIR}
|
|
)
|
|
|
|
include(SelectLibraryConfigurations)
|
|
select_library_configurations(ZSTD)
|
|
|
|
if(PC_ZSTD_VERSION)
|
|
set(WrapZSTD_VERSION "${PC_ZSTD_VERSION}")
|
|
endif()
|
|
find_package_handle_standard_args(WrapZSTD
|
|
REQUIRED_VARS ZSTD_LIBRARIES ZSTD_INCLUDE_DIRS
|
|
VERSION_VAR WrapZSTD_VERSION)
|
|
|
|
if(WrapZSTD_FOUND AND NOT TARGET WrapZSTD::WrapZSTD)
|
|
add_library(WrapZSTD::WrapZSTD UNKNOWN IMPORTED)
|
|
set_target_properties(WrapZSTD::WrapZSTD PROPERTIES
|
|
INTERFACE_INCLUDE_DIRECTORIES "${ZSTD_INCLUDE_DIRS}")
|
|
set_target_properties(WrapZSTD::WrapZSTD PROPERTIES
|
|
IMPORTED_LOCATION "${ZSTD_LIBRARY}")
|
|
if(ZSTD_LIBRARY_RELEASE)
|
|
set_target_properties(WrapZSTD::WrapZSTD PROPERTIES
|
|
IMPORTED_LOCATION_RELEASE "${ZSTD_LIBRARY_RELEASE}")
|
|
endif()
|
|
if(ZSTD_LIBRARY_DEBUG)
|
|
set_target_properties(WrapZSTD::WrapZSTD PROPERTIES
|
|
IMPORTED_LOCATION_DEBUG "${ZSTD_LIBRARY_DEBUG}")
|
|
endif()
|
|
endif()
|
|
|
|
mark_as_advanced(ZSTD_INCLUDE_DIRS ZSTD_LIBRARIES ZSTD_LIBRARY_RELEASE ZSTD_LIBRARY_DEBUG)
|
|
endif()
|
|
include(FeatureSummary)
|
|
set_package_properties(WrapZSTD PROPERTIES
|
|
URL "https://github.com/facebook/zstd"
|
|
DESCRIPTION "ZSTD compression library")
|
|
|