vasilito
7686729069
Extract protocol-agnostic FenceTimeline from Intel to shared src/drivers/fence.rs — atomic-based fence tracking suitable for Intel, VIRGL, and AMD drivers. Extract protocol-agnostic SyncobjManager from Intel to shared src/drivers/syncobj.rs — syncobj create/destroy/signal/reset/ wait/query and sync_file fd export/import. Wire both into VirtioDriver: - Add FenceTimeline + SyncobjManager fields - Implement all 5 GpuDriver syncobj trait methods (create, destroy, wait, export_fd, import_fd) - Track fence seqnos in virgl_submit_3d (allocate before submit, signal after completion) Intel fence.rs and syncobj.rs converted to thin re-export modules pointing at shared sources — no behavioral change for Intel driver. This gives Mesa VIRGL userspace the standard DRM syncobj API for GPU/compositor synchronization.
39 lines
1.2 KiB
Plaintext
39 lines
1.2 KiB
Plaintext
# printf-frexp.m4 serial 5
|
|
dnl Copyright (C) 2007, 2009-2023 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl Check how to define printf_frexp() without linking with libm.
|
|
|
|
AC_DEFUN([gl_FUNC_PRINTF_FREXP],
|
|
[
|
|
AC_REQUIRE([gl_CHECK_FREXP_NO_LIBM])
|
|
if test $gl_cv_func_frexp_no_libm = yes; then
|
|
gl_FUNC_FREXP_WORKS
|
|
case "$gl_cv_func_frexp_works" in
|
|
*yes)
|
|
AC_DEFINE([HAVE_FREXP_IN_LIBC], [1],
|
|
[Define if the frexp function is available in libc.])
|
|
;;
|
|
esac
|
|
fi
|
|
|
|
AC_CACHE_CHECK([whether ldexp can be used without linking with libm],
|
|
[gl_cv_func_ldexp_no_libm],
|
|
[
|
|
AC_LINK_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[#include <math.h>
|
|
double x;
|
|
int y;]],
|
|
[[return ldexp (x, y) < 1;]])],
|
|
[gl_cv_func_ldexp_no_libm=yes],
|
|
[gl_cv_func_ldexp_no_libm=no])
|
|
])
|
|
if test $gl_cv_func_ldexp_no_libm = yes; then
|
|
AC_DEFINE([HAVE_LDEXP_IN_LIBC], [1],
|
|
[Define if the ldexp function is available in libc.])
|
|
fi
|
|
])
|