vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
69 lines
1.7 KiB
Plaintext
69 lines
1.7 KiB
Plaintext
equals(QMAKE_HOST.os, Windows) {
|
|
SETENV_PFX = "set "
|
|
SETENV_SFX = "&"
|
|
} else {
|
|
SETENV_PFX =
|
|
SETENV_SFX =
|
|
}
|
|
|
|
QMAKE_MAKE = $$(MAKE)
|
|
!isEmpty(QMAKE_MAKE) {
|
|
# We were called recursively. Use the same make.
|
|
} else: if(equals(MAKEFILE_GENERATOR, UNIX)|equals(MAKEFILE_GENERATOR, MINGW)) {
|
|
!equals(QMAKE_HOST.os, Windows): \
|
|
QMAKE_MAKE = make
|
|
else: \
|
|
QMAKE_MAKE = mingw32-make
|
|
} else: if(equals(MAKEFILE_GENERATOR, MSVC.NET)|equals(MAKEFILE_GENERATOR, MSBUILD)) {
|
|
QMAKE_MAKE = nmake
|
|
} else {
|
|
error("Configure tests are not supported with the $$MAKEFILE_GENERATOR Makefile generator.")
|
|
}
|
|
QMAKE_MAKE_NAME = $$basename(QMAKE_MAKE)
|
|
# Make sure we don't inherit MAKEFLAGS - -i in particular is fatal.
|
|
QMAKE_MAKE = "$${SETENV_PFX}MAKEFLAGS=$$SETENV_SFX $$QMAKE_MAKE"
|
|
|
|
QMAKE_PERSIST_LOG = false
|
|
QMAKE_PERSISTED_LOG =
|
|
|
|
defineTest(qtLog) {
|
|
write_file($$QMAKE_CONFIG_LOG, 1, append)
|
|
$$QMAKE_CONFIG_VERBOSE: for (l, 1): log("$$l$$escape_expand(\\n)")
|
|
$$QMAKE_PERSIST_LOG {
|
|
QMAKE_PERSISTED_LOG += $$1
|
|
export(QMAKE_PERSISTED_LOG)
|
|
}
|
|
}
|
|
|
|
defineTest(qtPersistLog) {
|
|
QMAKE_PERSIST_LOG = true
|
|
QMAKE_PERSISTED_LOG =
|
|
export(QMAKE_PERSIST_LOG)
|
|
export(QMAKE_PERSISTED_LOG)
|
|
}
|
|
|
|
defineReplace(qtPersistedLog) {
|
|
QMAKE_PERSIST_LOG = false
|
|
export(QMAKE_PERSIST_LOG)
|
|
return($$QMAKE_PERSISTED_LOG)
|
|
}
|
|
|
|
defineTest(qtRunLoggedCommand) {
|
|
qtLog("+ $$1")
|
|
|
|
!equals(3, false): \
|
|
1 = "( $$1 ) 2>&1"
|
|
output = $$system("$$1", lines, result)
|
|
lg =
|
|
for (l, output): \
|
|
lg += "> $$l"
|
|
qtLog($$lg)
|
|
!isEmpty(2) {
|
|
$$2 = $$output
|
|
export($$2)
|
|
}
|
|
|
|
!equals(result, 0): return(false)
|
|
return(true)
|
|
}
|