vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
99 lines
3.3 KiB
CMake
99 lines
3.3 KiB
CMake
# Copyright (C) 2025 The Qt Company Ltd.
|
|
# SPDX-License-Identifier: BSD-3-Clause
|
|
|
|
# The script allows signing of Android packages using either jarsigner or
|
|
# apksigner program.
|
|
#
|
|
# Usage:
|
|
# cmake -DPROGRAM=/path/to/signer [-DZIPALIGN_PATH=/path/to/zipalign]
|
|
# -DUNSIGNED_PACKAGE=path/to/input -DSIGNED_PACKAGE=path/to/output
|
|
# -P QtAndroidSignPackage.cmake
|
|
|
|
if(NOT DEFINED PROGRAM)
|
|
message(FATAL_ERROR "PROGRAM variable is not defined. Please"
|
|
" specify the path to the apksigner or jarsigner program.")
|
|
endif()
|
|
|
|
if(NOT DEFINED UNSIGNED_PACKAGE)
|
|
message(FATAL_ERROR "UNSIGNED_PACKAGE variable is not defined. Please"
|
|
" specify the path to the input file.")
|
|
endif()
|
|
|
|
if(NOT DEFINED SIGNED_PACKAGE)
|
|
message(FATAL_ERROR "SIGNED_PACKAGE variable is not defined. Please"
|
|
" specify the path to the output file.")
|
|
endif()
|
|
|
|
get_filename_component(program_name "${PROGRAM}" NAME_WE)
|
|
get_filename_component(type "${UNSIGNED_PACKAGE}" LAST_EXT)
|
|
if(type STREQUAL ".aab")
|
|
if(NOT program_name STREQUAL "jarsigner")
|
|
message(WARNING "Unexpected signer program for .aab files: ${program_name}. "
|
|
"Expected 'jarsigner'.")
|
|
endif()
|
|
|
|
set(digestalg "SHA-256")
|
|
set(sigalg "SHA256withRSA")
|
|
|
|
if(DEFINED ENV{QT_ANDROID_KEYSTORE_KEY_PASS})
|
|
set(keypass_arg -keypass "$ENV{QT_ANDROID_KEYSTORE_KEY_PASS}")
|
|
else()
|
|
set(keypass_arg "")
|
|
endif()
|
|
|
|
if(DEFINED ENV{QT_ANDROID_KEYSTORE_STORE_PASS})
|
|
set(storepass_arg -storepass "$ENV{QT_ANDROID_KEYSTORE_STORE_PASS}")
|
|
else()
|
|
set(storepass_arg "")
|
|
endif()
|
|
|
|
execute_process(
|
|
COMMAND ${PROGRAM}
|
|
-sigalg ${sigalg} -digestalg ${digestalg}
|
|
-keystore "$ENV{QT_ANDROID_KEYSTORE_PATH}"
|
|
${storepass_arg}
|
|
${keypass_arg}
|
|
-signedjar "${SIGNED_PACKAGE}"
|
|
"${UNSIGNED_PACKAGE}"
|
|
"$ENV{QT_ANDROID_KEYSTORE_ALIAS}"
|
|
RESULT_VARIABLE sign_result
|
|
OUTPUT_VARIABLE sign_output
|
|
ERROR_VARIABLE sign_error
|
|
)
|
|
|
|
if(NOT sign_result EQUAL 0)
|
|
message(FATAL_ERROR "Unable to sign ${UNSIGNED_PACKAGE}: ${sign_output} ${sign_error}")
|
|
endif()
|
|
elseif(type STREQUAL ".apk")
|
|
if(NOT DEFINED ZIPALIGN_PATH)
|
|
message(FATAL_ERROR "ZIPALIGN_PATH variable is not defined. Please"
|
|
" specify the path to the zipalign program.")
|
|
endif()
|
|
|
|
if(NOT program_name STREQUAL "apksigner")
|
|
message(WARNING "Unexpected signer program for .apk files: ${program_name}. "
|
|
"Expected 'apksigner'.")
|
|
endif()
|
|
|
|
execute_process(
|
|
COMMAND "${ZIPALIGN_PATH}" -c 4 "${UNSIGNED_PACKAGE}")
|
|
|
|
execute_process(
|
|
COMMAND "${PROGRAM}" sign
|
|
--ks "$ENV{QT_ANDROID_KEYSTORE_PATH}"
|
|
--ks-pass "pass:$ENV{QT_ANDROID_KEYSTORE_STORE_PASS}"
|
|
--key-pass "pass:$ENV{QT_ANDROID_KEYSTORE_KEY_PASS}"
|
|
--ks-key-alias "$ENV{QT_ANDROID_KEYSTORE_ALIAS}"
|
|
--out "${SIGNED_PACKAGE}" "${UNSIGNED_PACKAGE}"
|
|
RESULT_VARIABLE sign_result
|
|
OUTPUT_VARIABLE sign_output
|
|
ERROR_VARIABLE sign_error
|
|
)
|
|
|
|
if(NOT sign_result EQUAL 0)
|
|
message(FATAL_ERROR "Unable to sign ${UNSIGNED_PACKAGE}: ${sign_output} ${sign_error}")
|
|
endif()
|
|
else()
|
|
message(FATAL_ERROR "Unsupported file type: ${type}. Only .apk and .aab files are supported.")
|
|
endif()
|