vasilito
068a1ca63e
Bootloader fork rebase:
- Base changed from 0.1.0 pre-patched archive to upstream 1.0.0 tag (c7eeb9f)
- Applied 0001-redbear-local-forks.patch (Cargo.toml crate path redirects)
- Applied fix-uefi-alloc-panic.patch equivalents (4 panic!() -> graceful
error handling in src/main.rs)
- Applied P5-live-preload-cap-1gib.patch (1 GiB cap on live image preload)
- Skipped: P0 GPT partition scan (requires new module + integration),
P1 timeout/default-resolution, P2 live preload guard (subsumed by
panic fixes + cap), P3 live image safe read, P4 large ISO boot,
redox.patch — to be applied in dedicated rebase session.
firmware-loader/Cargo.toml: version 0.1.0 -> 0.3.0 (sync with other
Red Bear custom crates which are at 0.3.0).
fork-upstream-map.toml: bootloader back from PENDING_REBASE to 1.0.0
since the partial rebase matches upstream 1.0.0 content.
fork-upstream-map.toml: base restored to 'main' tracked (was correctly
tracked by build-redbear.sh).
62 lines
1.9 KiB
Plaintext
62 lines
1.9 KiB
Plaintext
# getprogname.m4
|
|
# serial 8
|
|
dnl Copyright (C) 2016-2025 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
dnl This file is offered as-is, without any warranty.
|
|
|
|
# Check for getprogname or replacements for it
|
|
|
|
AC_DEFUN([gl_FUNC_GETPROGNAME],
|
|
[
|
|
AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
|
|
AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
|
|
gl_CHECK_FUNCS_ANDROID([getprogname], [[#include <stdlib.h>]])
|
|
if test $ac_cv_func_getprogname = no; then
|
|
HAVE_GETPROGNAME=0
|
|
case "$gl_cv_onwards_func_getprogname" in
|
|
future*) REPLACE_GETPROGNAME=1 ;;
|
|
esac
|
|
fi
|
|
AC_CHECK_DECLS([program_invocation_name],
|
|
[],
|
|
[HAVE_DECL_PROGRAM_INVOCATION_NAME=0],
|
|
[[#include <errno.h>]])
|
|
])
|
|
|
|
AC_DEFUN([gl_PREREQ_GETPROGNAME],
|
|
[
|
|
AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
|
|
AC_CHECK_FUNCS_ONCE([getexecname])
|
|
ac_found=0
|
|
AC_CHECK_DECLS([program_invocation_name], [ac_found=1], [],
|
|
[#include <errno.h>])
|
|
AC_CHECK_DECLS([program_invocation_short_name], [ac_found=1], [],
|
|
[#include <errno.h>])
|
|
AC_CHECK_DECLS([__argv], [ac_found=1], [], [#include <stdlib.h>])
|
|
|
|
# Incur the cost of this test only if none of the above worked.
|
|
if test $ac_found = 0; then
|
|
# On OpenBSD 5.1, using the global __progname variable appears to be
|
|
# the only way to implement getprogname.
|
|
AC_CACHE_CHECK([whether __progname is defined in default libraries],
|
|
[gl_cv_var___progname],
|
|
[
|
|
gl_cv_var___progname=
|
|
AC_LINK_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[extern char *__progname;]],
|
|
[[return *__progname;]]
|
|
)],
|
|
[gl_cv_var___progname=yes]
|
|
)
|
|
]
|
|
)
|
|
if test "$gl_cv_var___progname" = yes; then
|
|
AC_DEFINE([HAVE_VAR___PROGNAME], 1,
|
|
[Define if you have a global __progname variable])
|
|
fi
|
|
fi
|
|
])
|