vasilito
068a1ca63e
Bootloader fork rebase:
- Base changed from 0.1.0 pre-patched archive to upstream 1.0.0 tag (c7eeb9f)
- Applied 0001-redbear-local-forks.patch (Cargo.toml crate path redirects)
- Applied fix-uefi-alloc-panic.patch equivalents (4 panic!() -> graceful
error handling in src/main.rs)
- Applied P5-live-preload-cap-1gib.patch (1 GiB cap on live image preload)
- Skipped: P0 GPT partition scan (requires new module + integration),
P1 timeout/default-resolution, P2 live preload guard (subsumed by
panic fixes + cap), P3 live image safe read, P4 large ISO boot,
redox.patch — to be applied in dedicated rebase session.
firmware-loader/Cargo.toml: version 0.1.0 -> 0.3.0 (sync with other
Red Bear custom crates which are at 0.3.0).
fork-upstream-map.toml: bootloader back from PENDING_REBASE to 1.0.0
since the partial rebase matches upstream 1.0.0 content.
fork-upstream-map.toml: base restored to 'main' tracked (was correctly
tracked by build-redbear.sh).
79 lines
2.8 KiB
Plaintext
79 lines
2.8 KiB
Plaintext
# fchdir.m4
|
|
# serial 32
|
|
dnl Copyright (C) 2006-2025 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
dnl This file is offered as-is, without any warranty.
|
|
|
|
AC_DEFUN([gl_FUNC_FCHDIR],
|
|
[
|
|
AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
|
|
AC_REQUIRE([gl_DIRENT_H_DEFAULTS])
|
|
AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
|
|
|
|
AC_CHECK_DECLS_ONCE([fchdir])
|
|
if test $ac_cv_have_decl_fchdir = no; then
|
|
HAVE_DECL_FCHDIR=0
|
|
fi
|
|
|
|
AC_REQUIRE([gl_TEST_FCHDIR])
|
|
if test $HAVE_FCHDIR = 1; then
|
|
AC_REQUIRE([gl_DIRENT_DIR])
|
|
if test $DIR_HAS_FD_MEMBER = 0; then
|
|
dnl fchdir() should be replaced if dirfd() does not work.
|
|
REPLACE_FCHDIR=1
|
|
fi
|
|
fi
|
|
|
|
if test $HAVE_FCHDIR = 0 || test $REPLACE_FCHDIR = 1; then
|
|
AC_DEFINE([REPLACE_FCHDIR], [1],
|
|
[Define to 1 if gnulib's fchdir() replacement is used.])
|
|
dnl We must also replace anything that can manipulate a directory fd,
|
|
dnl to keep our bookkeeping up-to-date. We don't have to replace
|
|
dnl fstatat, since no platform has fstatat but lacks fchdir.
|
|
AC_CACHE_CHECK([whether open can visit directories],
|
|
[gl_cv_func_open_directory_works],
|
|
[AC_RUN_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[#include <fcntl.h>
|
|
]GL_MDA_DEFINES],
|
|
[[return open(".", O_RDONLY) < 0;]])],
|
|
[gl_cv_func_open_directory_works=yes],
|
|
[gl_cv_func_open_directory_works=no],
|
|
[case "$host_os" in
|
|
# Guess yes on Linux systems.
|
|
linux-* | linux) gl_cv_func_open_directory_works="guessing yes" ;;
|
|
# Guess yes on systems that emulate the Linux system calls.
|
|
midipix*) gl_cv_func_open_directory_works="guessing yes" ;;
|
|
# Guess yes on glibc systems.
|
|
*-gnu* | gnu*) gl_cv_func_open_directory_works="guessing yes" ;;
|
|
# Guess no on native Windows.
|
|
mingw* | windows*) gl_cv_func_open_directory_works="guessing no" ;;
|
|
# If we don't know, obey --enable-cross-guesses.
|
|
*) gl_cv_func_open_directory_works="$gl_cross_guess_normal" ;;
|
|
esac
|
|
])])
|
|
case "$gl_cv_func_open_directory_works" in
|
|
*yes) ;;
|
|
*)
|
|
AC_DEFINE([REPLACE_OPEN_DIRECTORY], [1], [Define to 1 if open() should
|
|
work around the inability to open a directory.])
|
|
;;
|
|
esac
|
|
fi
|
|
])
|
|
|
|
# Determine whether to use the overrides in lib/fchdir.c.
|
|
AC_DEFUN([gl_TEST_FCHDIR],
|
|
[
|
|
AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
|
|
AC_CHECK_FUNCS_ONCE([fchdir])
|
|
if test $ac_cv_func_fchdir = no; then
|
|
HAVE_FCHDIR=0
|
|
fi
|
|
])
|
|
|
|
# Prerequisites of lib/fchdir.c.
|
|
AC_DEFUN([gl_PREREQ_FCHDIR], [:])
|