vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
55 lines
1.6 KiB
CMake
55 lines
1.6 KiB
CMake
# Copyright (C) 2022 The Qt Company Ltd.
|
|
# SPDX-License-Identifier: BSD-3-Clause
|
|
|
|
# We can't create the same interface imported target multiple times, CMake will complain if we do
|
|
# that. This can happen if the find_package call is done in multiple different subdirectories.
|
|
if(TARGET WrapAtomic::WrapAtomic)
|
|
set(WrapAtomic_FOUND ON)
|
|
return()
|
|
endif()
|
|
|
|
include(CheckCXXSourceCompiles)
|
|
|
|
set (atomic_test_sources "#include <atomic>
|
|
#include <cstdint>
|
|
|
|
int main(int, char **)
|
|
{
|
|
volatile std::atomic<char> size_1;
|
|
volatile std::atomic<short> size_2;
|
|
volatile std::atomic<int> size_4;
|
|
volatile std::atomic<int64_t> size_8;
|
|
|
|
++size_1;
|
|
++size_2;
|
|
++size_4;
|
|
++size_8;
|
|
|
|
(void)size_1.load(std::memory_order_relaxed);
|
|
(void)size_2.load(std::memory_order_relaxed);
|
|
(void)size_4.load(std::memory_order_relaxed);
|
|
(void)size_8.load(std::memory_order_relaxed);
|
|
|
|
return 0;
|
|
}")
|
|
|
|
check_cxx_source_compiles("${atomic_test_sources}" HAVE_STDATOMIC)
|
|
if(NOT HAVE_STDATOMIC)
|
|
set(_req_libraries "${CMAKE_REQUIRED_LIBRARIES}")
|
|
set(atomic_LIB "-latomic")
|
|
set(CMAKE_REQUIRED_LIBRARIES ${atomic_LIB})
|
|
check_cxx_source_compiles("${atomic_test_sources}" HAVE_STDATOMIC_WITH_LIB)
|
|
set(CMAKE_REQUIRED_LIBRARIES "${_req_libraries}")
|
|
endif()
|
|
|
|
add_library(WrapAtomic::WrapAtomic INTERFACE IMPORTED)
|
|
if(HAVE_STDATOMIC_WITH_LIB)
|
|
# atomic_LIB is already found above.
|
|
target_link_libraries(WrapAtomic::WrapAtomic INTERFACE ${atomic_LIB})
|
|
endif()
|
|
|
|
set(WrapAtomic_FOUND 1)
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(WrapAtomic DEFAULT_MSG WrapAtomic_FOUND)
|