vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
91 lines
2.6 KiB
QML
91 lines
2.6 KiB
QML
// Copyright (C) 2018 The Qt Company Ltd.
|
|
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
|
|
|
|
import QtQuick
|
|
import QtQuick.Window
|
|
import QtWayland.Compositor
|
|
import QtWayland.Compositor.XdgShell
|
|
|
|
WaylandCompositor {
|
|
WaylandOutput {
|
|
sizeFollowsWindow: true
|
|
window: Window {
|
|
id: topSurfaceArea
|
|
|
|
property int pixelHeight: screen.devicePixelRatio * height
|
|
property int pixelWidth: screen.devicePixelRatio * width
|
|
|
|
width: 1024
|
|
height: 768
|
|
visible: true
|
|
color: "#1337af"
|
|
|
|
Text { text: "Top screen" }
|
|
|
|
// ![enable screens]
|
|
// Enable the following to make the output target an actual screen,
|
|
// for example when running on eglfs in a multi-display embedded system.
|
|
|
|
// screen: Qt.application.screens[0]
|
|
// ![enable screens]
|
|
}
|
|
}
|
|
|
|
WaylandOutput {
|
|
sizeFollowsWindow: true
|
|
window: Window {
|
|
id: bottomSurfaceArea
|
|
|
|
property int pixelHeight: screen.devicePixelRatio * height
|
|
property int pixelWidth: screen.devicePixelRatio * width
|
|
|
|
width: 1024
|
|
height: 768
|
|
visible: true
|
|
color: "#1abacc"
|
|
|
|
Text { text: "Bottom screen" }
|
|
|
|
// Enable the following to make the output target an actual screen,
|
|
// for example when running on eglfs in a multi-display embedded system.
|
|
|
|
// screen: Qt.application.screens[1]
|
|
}
|
|
}
|
|
|
|
Component {
|
|
id: chromeComponent
|
|
Item {
|
|
property alias shellSurface: ssi.shellSurface
|
|
ShellSurfaceItem {
|
|
id: ssi
|
|
onSurfaceDestroyed: destroy()
|
|
}
|
|
}
|
|
}
|
|
|
|
XdgShell {
|
|
onToplevelCreated: (toplevel, xdgSurface) => {
|
|
const shellSurface = xdgSurface;
|
|
|
|
// ![create items]
|
|
const topItem = chromeComponent.createObject(topSurfaceArea, {
|
|
shellSurface
|
|
});
|
|
|
|
const bottomItem = chromeComponent.createObject(bottomSurfaceArea, {
|
|
shellSurface,
|
|
y: Qt.binding(function() { return -topSurfaceArea.height;})
|
|
});
|
|
// ![create items]
|
|
|
|
// ![size]
|
|
const height = topSurfaceArea.pixelHeight + bottomSurfaceArea.pixelHeight;
|
|
const width = Math.max(bottomSurfaceArea.pixelWidth, topSurfaceArea.pixelWidth);
|
|
const size = Qt.size(width, height);
|
|
toplevel.sendFullscreen(size);
|
|
// ![size]
|
|
}
|
|
}
|
|
}
|