vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
41 lines
991 B
Plaintext
41 lines
991 B
Plaintext
|
|
isEmpty(QMAKE_INFO_PLIST): \
|
|
return()
|
|
|
|
plist_path = $$absolute_path($$QMAKE_INFO_PLIST, $$_PRO_FILE_PWD_)
|
|
|
|
!exists($$plist_path): \
|
|
return()
|
|
|
|
for(plugin, QT_PLUGINS) {
|
|
!equals(QT_PLUGIN.$${plugin}.TYPE, permissions): \
|
|
next()
|
|
|
|
usage_descriptions = $$eval(QT_PLUGIN.$${plugin}.usage_descriptions)
|
|
|
|
found_usage_description = false
|
|
for(usage_description_key, usage_descriptions) {
|
|
usage_description = $$system("/usr/libexec/PlistBuddy" \
|
|
"-c 'print $$usage_description_key' $$plist_path 2>/dev/null", \
|
|
singleLine, exit_code)
|
|
|
|
!equals(exit_code, 0): \
|
|
next()
|
|
|
|
!isEmpty(usage_description) {
|
|
found_usage_description = true
|
|
break()
|
|
}
|
|
}
|
|
|
|
!$$found_usage_description: \
|
|
next()
|
|
|
|
request_flag = $$eval(QT_PLUGIN.$${plugin}.request_flag)
|
|
|
|
QTPLUGIN += $$plugin
|
|
QMAKE_LFLAGS += $$request_flag
|
|
|
|
QMAKE_INTERNAL_INCLUDED_FILES *= $$QMAKE_INFO_PLIST
|
|
}
|