vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
43 lines
1.6 KiB
Plaintext
43 lines
1.6 KiB
Plaintext
# Automatically generate .qm files out of .ts files in TRANSLATIONS and
|
|
# EXTRA_TRANSLATIONS.
|
|
#
|
|
# If embed_translations is enabled, the generated .qm files are made available
|
|
# in the resource system under :/i18n/.
|
|
#
|
|
# Otherwise, the .qm files are available in the build directory in LRELEASE_DIR.
|
|
# They can also be automatically installed by setting QM_FILES_INSTALL_PATH.
|
|
|
|
qtPrepareTool(QMAKE_LRELEASE, lrelease)
|
|
|
|
isEmpty(LRELEASE_DIR): LRELEASE_DIR = .qm
|
|
isEmpty(QM_FILES_RESOURCE_PREFIX): QM_FILES_RESOURCE_PREFIX = i18n
|
|
|
|
lrelease.name = lrelease
|
|
lrelease.input = TRANSLATIONS EXTRA_TRANSLATIONS
|
|
lrelease.output = $$LRELEASE_DIR/${QMAKE_FILE_IN_BASE}.qm
|
|
lrelease.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} $$QMAKE_LRELEASE_FLAGS -qm ${QMAKE_FILE_OUT}
|
|
silent: lrelease.commands = @echo lrelease ${QMAKE_FILE_IN} && $$lrelease.commands
|
|
lrelease.CONFIG = no_link
|
|
QMAKE_EXTRA_COMPILERS += lrelease
|
|
|
|
all_translations = $$TRANSLATIONS $$EXTRA_TRANSLATIONS
|
|
for (translation, all_translations) {
|
|
# mirrors $$LRELEASE_DIR/${QMAKE_FILE_IN_BASE}.qm above
|
|
translation = $$basename(translation)
|
|
QM_FILES += $$OUT_PWD/$$LRELEASE_DIR/$$replace(translation, \\.[^.]+$, .qm)
|
|
}
|
|
embed_translations {
|
|
qmake_qm_files.files = $$QM_FILES
|
|
qmake_qm_files.base = $$OUT_PWD/$$LRELEASE_DIR
|
|
qmake_qm_files.prefix = $$QM_FILES_RESOURCE_PREFIX
|
|
RESOURCES += qmake_qm_files
|
|
} else {
|
|
!isEmpty(QM_FILES_INSTALL_PATH) {
|
|
qm_files.files = $$QM_FILES
|
|
qm_files.path = $$QM_FILES_INSTALL_PATH
|
|
qm_files.CONFIG = no_check_exist
|
|
INSTALLS += qm_files
|
|
}
|
|
lrelease.CONFIG += target_predeps no_clean
|
|
}
|