vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
87 lines
2.4 KiB
QML
87 lines
2.4 KiB
QML
// Copyright (C) 2021 The Qt Company Ltd.
|
|
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
|
|
|
|
import QtQuick
|
|
|
|
Item {
|
|
width: 640
|
|
height: 480
|
|
|
|
Rectangle {
|
|
id: map
|
|
color: "aqua"
|
|
x: (parent.width - width) / 2
|
|
y: (parent.height - height) / 2
|
|
width: image.width
|
|
height: image.height
|
|
transform: Rotation {
|
|
id: tilt
|
|
origin.x: width / 2
|
|
origin.y: height / 2
|
|
axis { x: 1; y: 0; z: 0 }
|
|
angle: tiltHandler.persistentTranslation.y / -2
|
|
}
|
|
|
|
WheelHandler {
|
|
id: wheelHandler
|
|
objectName: "vertical mouse wheel for scaling"
|
|
property: "scale"
|
|
onWheel: function(event) {
|
|
console.log("rotation " + event.angleDelta + " scaled " + rotation + " @ " + point.position + " => " + map.scale)
|
|
}
|
|
}
|
|
|
|
WheelHandler {
|
|
id: horizontalWheelHandler
|
|
objectName: "horizontal mouse wheel for side-scrolling"
|
|
property: "x"
|
|
orientation: Qt.Horizontal
|
|
}
|
|
|
|
Image {
|
|
id: image
|
|
anchors.centerIn: parent
|
|
fillMode: Image.PreserveAspectFit
|
|
source: "images/map.svgz"
|
|
Component.onCompleted: { width = implicitWidth; height = implicitHeight }
|
|
}
|
|
|
|
Text {
|
|
anchors.centerIn: parent
|
|
text: image.sourceSize.width + " x " + image.sourceSize.height +
|
|
" scale " + map.scale.toFixed(2) + " active scale " + pinch.activeScale.toFixed(2)
|
|
}
|
|
}
|
|
|
|
DragHandler {
|
|
objectName: "single-point drag"
|
|
target: map
|
|
}
|
|
|
|
DragHandler {
|
|
id: tiltHandler
|
|
objectName: "two-point tilt"
|
|
minimumPointCount: 2
|
|
maximumPointCount: 2
|
|
xAxis.enabled: false
|
|
target: null
|
|
}
|
|
|
|
PinchHandler {
|
|
id: pinch
|
|
objectName: "two-point pinch"
|
|
target: map
|
|
minimumScale: 0.1
|
|
maximumScale: 10
|
|
onActiveChanged: if (!active) reRenderIfNecessary()
|
|
grabPermissions: PinchHandler.TakeOverForbidden // don't allow takeover if pinch has started
|
|
}
|
|
|
|
function reRenderIfNecessary() {
|
|
var newSourceWidth = image.sourceSize.width * pinch.scale
|
|
var ratio = newSourceWidth / image.sourceSize.width
|
|
if (ratio > 1.1 || ratio < 0.9)
|
|
image.sourceSize.width = newSourceWidth
|
|
}
|
|
}
|