vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
51 lines
1.7 KiB
Plaintext
51 lines
1.7 KiB
Plaintext
#
|
|
# Lex extra-compiler for handling files specified in the LEXSOURCES variable
|
|
#
|
|
|
|
isEmpty(LEX_DIR): LEX_DIR = .
|
|
|
|
defineReplace(lexCommands) {
|
|
input = $$relative_path($$absolute_path($$1, $$OUT_PWD), $$OUT_PWD/$$LEX_DIR)
|
|
output = $$basename(2)
|
|
input_base = $$basename(1)
|
|
input_base ~= s/\.[^.]*$//
|
|
|
|
isEmpty(QMAKE_LEXFLAGS_MANGLE): QMAKE_LEXFLAGS_MANGLE = -P$${input_base}
|
|
QMAKE_LEXEXTRAFLAGS = $$QMAKE_LEXFLAGS
|
|
!yacc_no_name_mangle: QMAKE_LEXEXTRAFLAGS += $$QMAKE_LEXFLAGS_MANGLE
|
|
|
|
contains(QMAKE_LEX, .*flex) {
|
|
# GNU flex, we can use -o outfile
|
|
commands = $$QMAKE_LEX $$QMAKE_LEXEXTRAFLAGS --nounistd -o $$output $$input
|
|
} else {
|
|
# stupid POSIX lex, it only generates a file called lex.yy.c
|
|
# or lex.prefix.c if the -P<prefix> option is active
|
|
intermediate_file = lex.yy.c
|
|
QMAKE_LEXEXTRAFLAGS = $$QMAKE_LEXFLAGS $$QMAKE_LEXFLAGS_MANGLE
|
|
|
|
commands = \
|
|
-$(DEL_FILE) $${output}$$escape_expand(\\n\\t) \
|
|
$$QMAKE_LEX $$QMAKE_LEXEXTRAFLAGS $${input}$$escape_expand(\\n\\t) \
|
|
$(MOVE) $$intermediate_file $$output $$escape_expand(\\n\\t)
|
|
}
|
|
!equals(LEX_DIR, .): \
|
|
commands = cd $$LEX_DIR && $$commands
|
|
silent: commands = @echo Lex $$1 && $$commands
|
|
return($$commands)
|
|
}
|
|
|
|
{
|
|
lex.name = Lex ${QMAKE_FILE_IN}
|
|
lex.input = LEXSOURCES
|
|
lex.dependency_type = TYPE_C
|
|
lex_included {
|
|
lex.CONFIG += no_link
|
|
} else {
|
|
lex.variable_out = GENERATED_SOURCES
|
|
}
|
|
|
|
lex.commands = ${QMAKE_FUNC_lexCommands}
|
|
lex.output = $$LEX_DIR/$${QMAKE_CPP_MOD_MOC}${QMAKE_FILE_BASE}$${QMAKE_MOD_LEX}$${first(QMAKE_EXT_CPP)}
|
|
QMAKE_EXTRA_COMPILERS += lex
|
|
}
|