vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
51 lines
1.4 KiB
CMake
51 lines
1.4 KiB
CMake
# Copyright (C) 2022 The Qt Company Ltd.
|
|
# SPDX-License-Identifier: BSD-3-Clause
|
|
|
|
# DBus1 is buggy and breaks PKG_CONFIG environment.
|
|
# Work around that:-/
|
|
# See https://gitlab.freedesktop.org/dbus/dbus/issues/267 for more information
|
|
|
|
# When doing top-level static Qt builds, we need to protect against double creation of the dbus
|
|
# target.
|
|
if(DBus1_FOUND OR WrapDBus1_FOUND OR TARGET dbus-1)
|
|
set(WrapDBus1_FOUND 1)
|
|
return()
|
|
endif()
|
|
|
|
if(DEFINED ENV{PKG_CONFIG_DIR})
|
|
set(__qt_dbus_pcd "$ENV{PKG_CONFIG_DIR}")
|
|
endif()
|
|
if(DEFINED ENV{PKG_CONFIG_PATH})
|
|
set(__qt_dbus_pcp "$ENV{PKG_CONFIG_PATH}")
|
|
endif()
|
|
if(DEFINED ENV{PKG_CONFIG_LIBDIR})
|
|
set(__qt_dbus_pcl "$ENV{PKG_CONFIG_LIBDIR}")
|
|
endif()
|
|
|
|
find_package(DBus1 ${${CMAKE_FIND_PACKAGE_NAME}_FIND_VERSION} QUIET)
|
|
|
|
if(DEFINED __qt_dbus_pcd)
|
|
set(ENV{PKG_CONFIG_DIR} "${__qt_dbus_pcd}")
|
|
else()
|
|
unset(ENV{PKG_CONFIG_DIR})
|
|
endif()
|
|
if(DEFINED __qt_dbus_pcp)
|
|
set(ENV{PKG_CONFIG_PATH} "${__qt_dbus_pcp}")
|
|
else()
|
|
unset(ENV{PKG_CONFIG_PATH})
|
|
endif()
|
|
if(DEFINED __qt_dbus_pcl)
|
|
set(ENV{PKG_CONFIG_LIBDIR} "${__qt_dbus_pcl}")
|
|
else()
|
|
unset(ENV{PKG_CONFIG_LIBDIR})
|
|
endif()
|
|
|
|
if(DBus1_FOUND)
|
|
set(WrapDBus1_FOUND 1)
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(WrapDBus1 REQUIRED_VARS
|
|
DBus1_LIBRARY DBus1_INCLUDE_DIR WrapDBus1_FOUND
|
|
VERSION_VAR DBus1_VERSION)
|