vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
86 lines
3.5 KiB
CMake
86 lines
3.5 KiB
CMake
# Copyright (C) 2022 The Qt Company Ltd.
|
|
# SPDX-License-Identifier: BSD-3-Clause
|
|
|
|
# We can't create the same interface imported target multiple times, CMake will complain if we do
|
|
# that. This can happen if the find_package call is done in multiple different subdirectories.
|
|
if(TARGET WrapSystemDoubleConversion::WrapSystemDoubleConversion)
|
|
set(WrapSystemDoubleConversion_FOUND ON)
|
|
return()
|
|
endif()
|
|
|
|
set(WrapSystemDoubleConversion_REQUIRED_VARS "__double_conversion_found")
|
|
|
|
# Find either Config package or Find module.
|
|
# Upstream can be built either with CMake and then provides a Config file, or with Scons in which
|
|
# case there's no Config file.
|
|
# A Find module might be provided by a 3rd party, for example Conan might generate a Find module.
|
|
find_package(double-conversion ${${CMAKE_FIND_PACKAGE_NAME}_FIND_VERSION} QUIET)
|
|
set(__double_conversion_target_name "double-conversion::double-conversion")
|
|
if(double-conversion_FOUND AND TARGET "${__double_conversion_target_name}")
|
|
set(__double_conversion_found TRUE)
|
|
# This ensures the Config file is shown in the fphsa message.
|
|
if(double-conversion_CONFIG)
|
|
list(PREPEND WrapSystemDoubleConversion_REQUIRED_VARS
|
|
double-conversion_CONFIG)
|
|
endif()
|
|
endif()
|
|
|
|
if(NOT __double_conversion_found)
|
|
list(PREPEND WrapSystemDoubleConversion_REQUIRED_VARS
|
|
DOUBLE_CONVERSION_LIBRARY DOUBLE_CONVERSION_INCLUDE_DIR)
|
|
|
|
find_path(DOUBLE_CONVERSION_INCLUDE_DIR
|
|
NAMES
|
|
double-conversion/double-conversion.h
|
|
)
|
|
|
|
find_library(DOUBLE_CONVERSION_LIBRARY_RELEASE NAMES double-conversion)
|
|
|
|
# We assume a possible debug build of this library to be named with a d suffix.
|
|
# Adjust accordingly if a different naming scheme is established.
|
|
find_library(DOUBLE_CONVERSION_LIBRARY_DEBUG NAMES double-conversiond)
|
|
|
|
include(SelectLibraryConfigurations)
|
|
select_library_configurations(DOUBLE_CONVERSION)
|
|
mark_as_advanced(DOUBLE_CONVERSION_INCLUDE_DIR DOUBLE_CONVERSION_LIBRARY)
|
|
set(DOUBLE_CONVERSION_INCLUDE_DIRS "${DOUBLE_CONVERSION_INCLUDE_DIR}")
|
|
|
|
if(DOUBLE_CONVERSION_LIBRARIES AND DOUBLE_CONVERSION_INCLUDE_DIRS)
|
|
set(__double_conversion_found TRUE)
|
|
endif()
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
|
|
set(__double_conversion_fphsa_args "")
|
|
if(double-conversion_VERSION)
|
|
set(WrapSystemDoubleConversion_VERSION "${double-conversion_VERSION}")
|
|
list(APPEND __double_conversion_fphsa_args VERSION_VAR WrapSystemDoubleConversion_VERSION)
|
|
endif()
|
|
|
|
find_package_handle_standard_args(WrapSystemDoubleConversion
|
|
REQUIRED_VARS ${WrapSystemDoubleConversion_REQUIRED_VARS}
|
|
${__double_conversion_fphsa_args})
|
|
|
|
if(WrapSystemDoubleConversion_FOUND)
|
|
add_library(WrapSystemDoubleConversion::WrapSystemDoubleConversion INTERFACE IMPORTED)
|
|
if(TARGET "${__double_conversion_target_name}")
|
|
target_link_libraries(WrapSystemDoubleConversion::WrapSystemDoubleConversion
|
|
INTERFACE "${__double_conversion_target_name}")
|
|
else()
|
|
target_link_libraries(WrapSystemDoubleConversion::WrapSystemDoubleConversion
|
|
INTERFACE ${DOUBLE_CONVERSION_LIBRARIES})
|
|
target_include_directories(WrapSystemDoubleConversion::WrapSystemDoubleConversion
|
|
INTERFACE ${DOUBLE_CONVERSION_INCLUDE_DIRS})
|
|
endif()
|
|
endif()
|
|
unset(__double_conversion_target_name)
|
|
unset(__double_conversion_found)
|
|
unset(__double_conversion_fphsa_args)
|
|
|
|
include(FeatureSummary)
|
|
set_package_properties(WrapSystemDoubleConversion PROPERTIES
|
|
URL "https://github.com/google/double-conversion"
|
|
DESCRIPTION "double-conversion library")
|
|
|