95 lines
3.3 KiB
CMake
95 lines
3.3 KiB
CMake
cmake_minimum_required(VERSION 3.16)
|
|
|
|
set(KF_VERSION "6.10.0") # handled by release scripts
|
|
project(KItemViews VERSION ${KF_VERSION})
|
|
|
|
include(FeatureSummary)
|
|
find_package(ECM 6.10.0 NO_MODULE)
|
|
set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
|
|
feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
|
|
|
|
set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
|
|
|
|
include(KDEInstallDirs)
|
|
include(KDECMakeSettings)
|
|
include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
|
|
|
|
include(KDEGitCommitHooks)
|
|
include(ECMGenerateExportHeader)
|
|
include(ECMSetupVersion)
|
|
include(ECMGenerateHeaders)
|
|
include(ECMQtDeclareLoggingCategory)
|
|
include(ECMDeprecationSettings)
|
|
include(ECMAddQch)
|
|
include(ECMPoQmTools)
|
|
include(CMakeDependentOption)
|
|
include(CMakePackageConfigHelpers)
|
|
|
|
set(REQUIRED_QT_VERSION 6.6.0)
|
|
find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Widgets)
|
|
find_package(Qt6GuiPrivate ${REQUIRED_QT_VERSION} REQUIRED)
|
|
|
|
set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
|
|
|
|
option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
|
|
add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
|
|
|
|
cmake_dependent_option(BUILD_DESIGNERPLUGIN "Build plugin for Qt Designer" ON "NOT CMAKE_CROSSCOMPILING" OFF)
|
|
add_feature_info(DESIGNERPLUGIN ${BUILD_DESIGNERPLUGIN} "Build plugin for Qt Designer")
|
|
|
|
set(kitemviews_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/kitemviews_version.h")
|
|
ecm_setup_version(PROJECT VARIABLE_PREFIX KITEMVIEWS
|
|
VERSION_HEADER "${kitemviews_version_header}"
|
|
PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6ItemViewsConfigVersion.cmake"
|
|
SOVERSION 6)
|
|
|
|
|
|
#ecm_install_po_files_as_qm(poqm)
|
|
|
|
ecm_set_disabled_deprecation_versions(
|
|
QT 6.8
|
|
)
|
|
|
|
add_subdirectory(src)
|
|
if (BUILD_TESTING)
|
|
add_subdirectory(autotests)
|
|
add_subdirectory(tests)
|
|
endif()
|
|
|
|
# create a Config.cmake and a ConfigVersion.cmake file and install them
|
|
set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6ItemViews")
|
|
|
|
if (BUILD_QCH)
|
|
ecm_install_qch_export(
|
|
TARGETS KF6ItemViews_QCH
|
|
FILE KF6ItemViewsQCHTargets.cmake
|
|
DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
|
|
)
|
|
set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6ItemViewsQCHTargets.cmake\")")
|
|
endif()
|
|
|
|
configure_package_config_file(
|
|
"${CMAKE_CURRENT_SOURCE_DIR}/KF6ItemViewsConfig.cmake.in"
|
|
"${CMAKE_CURRENT_BINARY_DIR}/KF6ItemViewsConfig.cmake"
|
|
INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
|
|
)
|
|
|
|
install(FILES
|
|
"${CMAKE_CURRENT_BINARY_DIR}/KF6ItemViewsConfig.cmake"
|
|
"${CMAKE_CURRENT_BINARY_DIR}/KF6ItemViewsConfigVersion.cmake"
|
|
DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
|
|
COMPONENT Devel
|
|
)
|
|
|
|
install(EXPORT KF6ItemViewsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6ItemViewsTargets.cmake NAMESPACE KF6:: )
|
|
|
|
install(FILES
|
|
${kitemviews_version_header}
|
|
DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KItemViews COMPONENT Devel
|
|
)
|
|
|
|
include(ECMFeatureSummary)
|
|
ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
|
|
|
|
kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
|