vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
48 lines
1.4 KiB
Meson
48 lines
1.4 KiB
Meson
icondir = get_option('icon_directory')
|
|
if icondir == ''
|
|
icondir = join_paths(get_option('prefix'), get_option('datadir'), 'icons')
|
|
endif
|
|
|
|
if wayland_version[0] != '1'
|
|
# The versioning used for the shared libraries assumes that the major
|
|
# version of Wayland as a whole will increase to 2 if and only if there
|
|
# is an ABI break, at which point we should probably bump the SONAME of
|
|
# all libraries to .so.2. For more details see
|
|
# https://gitlab.freedesktop.org/wayland/wayland/-/merge_requests/177
|
|
error('We probably need to bump the SONAME of libwayland-cursor')
|
|
endif
|
|
|
|
wayland_cursor = library(
|
|
'wayland-cursor',
|
|
sources: [
|
|
'wayland-cursor.c',
|
|
'os-compatibility.c',
|
|
'xcursor.c',
|
|
],
|
|
# To avoid an unnecessary SONAME bump, wayland 1.x.y produces
|
|
# libwayland-cursor.so.0.x.y.
|
|
version: '.'.join(['0', wayland_version[1], wayland_version[2]]),
|
|
dependencies: [ wayland_client_dep ],
|
|
c_args: [ '-DICONDIR="@0@"'.format(icondir) ],
|
|
install: true,
|
|
)
|
|
|
|
install_headers('wayland-cursor.h')
|
|
|
|
pkgconfig.generate(
|
|
name: 'Wayland Cursor',
|
|
description: 'Wayland cursor helper library',
|
|
version: meson.project_version(),
|
|
libraries: wayland_cursor,
|
|
filebase: 'wayland-cursor',
|
|
)
|
|
|
|
wayland_cursor_dep = declare_dependency(
|
|
link_with: wayland_cursor,
|
|
include_directories: [ root_inc, include_directories('.') ],
|
|
)
|
|
|
|
if meson.version().version_compare('>= 0.54.0')
|
|
meson.override_dependency('wayland-cursor', wayland_cursor_dep)
|
|
endif
|