vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
48 lines
1.9 KiB
Plaintext
48 lines
1.9 KiB
Plaintext
build_pass:console {
|
|
warning("QAxServer applications cannot be console applications.")
|
|
warning("Remove 'console' from your CONFIG.")
|
|
}
|
|
|
|
CONFIG -= entrypoint
|
|
|
|
ACTIVEQT_VERSION = $$VERSION
|
|
isEmpty(ACTIVEQT_VERSION):ACTIVEQT_VERSION = 1.0
|
|
|
|
qtPrepareTool(QMAKE_IDC, idc)
|
|
contains(TEMPLATE, "vc.*") {
|
|
ACTIVEQT_IDC = $${QMAKE_IDC}
|
|
ACTIVEQT_IDL = $${QMAKE_IDL}
|
|
ACTIVEQT_TARGET = \"$(TargetPath)\"
|
|
ACTIVEQT_NEWLINE = $$escape_expand(\\n\\t)
|
|
ACTIVEQT_OUTPUT = $(IntDir)$${TARGET}
|
|
ACTIVEQT_TLBOUT = \"$(TargetDir)/$${TARGET}.tlb\"
|
|
GENERATED += $${OBJECTS_DIR}/$${TARGET}.idl $${ACTIVEQT_TLBOUT}
|
|
} else {
|
|
ACTIVEQT_IDC = -$(IDC)
|
|
ACTIVEQT_IDL = -$(IDL)
|
|
ACTIVEQT_NEWLINE = $$escape_expand(\\n\\t)
|
|
ACTIVEQT_TARGET = $(DESTDIR_TARGET)
|
|
ACTIVEQT_OUTPUT = $(OBJECTS_DIR)/$${TARGET}
|
|
isEmpty(DESTDIR) {
|
|
ACTIVEQT_TLBOUT = $${TARGET}.tlb
|
|
} else {
|
|
ACTIVEQT_TLBOUT = $${DESTDIR}/$${TARGET}.tlb
|
|
}
|
|
}
|
|
|
|
!qaxserver_no_postlink {
|
|
!isEmpty(QMAKE_POST_LINK):QMAKE_POST_LINK += $$quote($$ACTIVEQT_NEWLINE)
|
|
QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDC $${ACTIVEQT_TARGET} /idl $${ACTIVEQT_OUTPUT}.idl -version $${ACTIVEQT_VERSION}$${ACTIVEQT_NEWLINE})
|
|
!isEmpty(RC_FILE) {
|
|
QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDL "$${ACTIVEQT_OUTPUT}.idl" /nologo /tlb "$${ACTIVEQT_OUTPUT}.tlb"$$ACTIVEQT_NEWLINE)
|
|
QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDC $${ACTIVEQT_TARGET} /tlb $${ACTIVEQT_OUTPUT}.tlb$$ACTIVEQT_NEWLINE)
|
|
} else {
|
|
QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDL "$${ACTIVEQT_OUTPUT}.idl" /nologo /tlb "$${ACTIVEQT_TLBOUT}"$$ACTIVEQT_NEWLINE)
|
|
message("No rc-file linked into project; type library will be a separate file.")
|
|
}
|
|
!qaxserver_no_register: \
|
|
QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDC $${ACTIVEQT_TARGET} /regserver)
|
|
QMAKE_CLEAN += $${ACTIVEQT_OUTPUT}.idl $${ACTIVEQT_OUTPUT}.tlb
|
|
}
|
|
|