vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
37 lines
1.2 KiB
Plaintext
37 lines
1.2 KiB
Plaintext
qtPrepareTool(QMAKE_DUMPCPP, dumpcpp)
|
|
|
|
dumpcpp_decl.depends += $$QMAKE_DUMPCPP_EXE
|
|
dumpcpp_decl.commands = $$QMAKE_DUMPCPP ${QMAKE_FILE_IN} -o ${QMAKE_FILE_BASE}
|
|
qaxcontainer_compat: dumpcpp_decl.commands += -compat
|
|
dumpcpp_decl.output = ${QMAKE_FILE_BASE}.h
|
|
dumpcpp_decl.input = TYPELIBS
|
|
dumpcpp_decl.variable_out = HEADERS
|
|
dumpcpp_decl.name = DUMP
|
|
dumpcpp_decl.CONFIG += no_link
|
|
|
|
QMAKE_EXTRA_COMPILERS += dumpcpp_decl
|
|
|
|
|
|
dumpcpp_impl.commands = $$escape_expand(\\n) # dummy command
|
|
dumpcpp_impl.output = ${QMAKE_FILE_BASE}.cpp
|
|
dumpcpp_impl.input = TYPELIBS
|
|
dumpcpp_impl.variable_out = SOURCES
|
|
dumpcpp_impl.name = CPP
|
|
dumpcpp_impl.depends += ${QMAKE_FILE_BASE}.h
|
|
|
|
QMAKE_EXTRA_COMPILERS += dumpcpp_impl
|
|
|
|
|
|
# Call dumpcpp the first time if the files do not exist to help find dependencies
|
|
!build_pass:have_target:!contains(TEMPLATE, vc.*) {
|
|
for(tlb, TYPELIBS) {
|
|
tlbCopy = $$replace(tlb, \", )
|
|
hdr = $$basename(tlbCopy)
|
|
hdr = $$section(hdr, ., 0, -2)
|
|
tmp_command = $$QMAKE_DUMPCPP $$system_quote($$absolute_path($$tlbCopy, $$_PRO_FILE_PWD_)) \
|
|
-o $$system_quote($$OUT_PWD/$$hdr)
|
|
qaxcontainer_compat: tmp_command += -compat
|
|
!exists($$OUT_PWD/$${hdr}.h): system($$tmp_command)
|
|
}
|
|
}
|