vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
82 lines
5.2 KiB
Plaintext
82 lines
5.2 KiB
Plaintext
#
|
|
# Extra-compilers for handling files specified in
|
|
# the WAYLANDSERVERSOURCES and WAYLANDCLIENTSOURCES variables.
|
|
#
|
|
# WAYLANDSERVERSOURCES_SYSTEM and WAYLANDCLIENTSOURCES_SYSTEM
|
|
# are for protocols where the wayland-scanner output is already
|
|
# included in the system libraries. In that case, .c files must
|
|
# not be generated, to avoid the Qt version replacing driver-specific
|
|
# functions. These files are therefore omitted from wayland_code.input.
|
|
# Header files are still generated because they are used to build QtWayland.
|
|
#
|
|
# qtwaylandscanner must be used even in the _SYSTEM case, since the system
|
|
# Wayland libraries do not contain Qt code.
|
|
|
|
isEmpty(QMAKE_WAYLAND_SCANNER):error("QMAKE_WAYLAND_SCANNER not defined for this mkspec")
|
|
|
|
!isEmpty(MODULE_INCNAME) {
|
|
WAYLAND_INCLUDE_DIR = $$MODULE_INCNAME/private
|
|
}
|
|
|
|
wayland_server_header.name = wayland ${QMAKE_FILE_BASE}
|
|
wayland_server_header.input = WAYLANDSERVERSOURCES WAYLANDSERVERSOURCES_SYSTEM
|
|
wayland_server_header.variable_out = HEADERS
|
|
wayland_server_header.output = wayland-${QMAKE_FILE_BASE}-server-protocol$${first(QMAKE_EXT_H)}
|
|
wayland_server_header.commands = $$QMAKE_WAYLAND_SCANNER --strict --include-core-only server-header < ${QMAKE_FILE_IN} > ${QMAKE_FILE_OUT}
|
|
silent:wayland_server_header.commands = @echo Wayland server header ${QMAKE_FILE_IN} && $$wayland_server_header.commands
|
|
QMAKE_EXTRA_COMPILERS += wayland_server_header
|
|
|
|
wayland_client_header.name = wayland ${QMAKE_FILE_BASE}
|
|
wayland_client_header.input = WAYLANDCLIENTSOURCES WAYLANDCLIENTSOURCES_SYSTEM
|
|
wayland_client_header.variable_out = HEADERS
|
|
wayland_client_header.output = wayland-${QMAKE_FILE_BASE}-client-protocol$${first(QMAKE_EXT_H)}
|
|
wayland_client_header.commands = $$QMAKE_WAYLAND_SCANNER --strict --include-core-only client-header < ${QMAKE_FILE_IN} > ${QMAKE_FILE_OUT}
|
|
silent:wayland_client_header.commands = @echo Wayland client header ${QMAKE_FILE_IN} && $$wayland_client_header.commands
|
|
QMAKE_EXTRA_COMPILERS += wayland_client_header
|
|
|
|
wayland_code.name = wayland ${QMAKE_FILE_BASE}
|
|
wayland_code.input = WAYLANDCLIENTSOURCES WAYLANDSERVERSOURCES
|
|
wayland_code.variable_out = SOURCES
|
|
wayland_code.output = wayland-${QMAKE_FILE_BASE}-protocol.c
|
|
wayland_code.commands = $$QMAKE_WAYLAND_SCANNER --strict --include-core-only public-code < ${QMAKE_FILE_IN} > ${QMAKE_FILE_OUT}
|
|
silent:wayland_code.commands = @echo Wayland code header ${QMAKE_FILE_IN} && $$wayland_code.commands
|
|
QMAKE_EXTRA_COMPILERS += wayland_code
|
|
|
|
qtPrepareLibExecTool(QMAKE_QTWAYLANDSCANNER, qtwaylandscanner)
|
|
|
|
qtwayland_client_header.name = qtwayland ${QMAKE_FILE_BASE}
|
|
qtwayland_client_header.input = WAYLANDCLIENTSOURCES WAYLANDCLIENTSOURCES_SYSTEM
|
|
qtwayland_client_header.variable_out = HEADERS
|
|
qtwayland_client_header.depends += $$QMAKE_QTWAYLANDSCANNER_EXE wayland-${QMAKE_FILE_BASE}-client-protocol$${first(QMAKE_EXT_H)}
|
|
qtwayland_client_header.output = qwayland-${QMAKE_FILE_BASE}$${first(QMAKE_EXT_H)}
|
|
qtwayland_client_header.commands = $$QMAKE_QTWAYLANDSCANNER client-header ${QMAKE_FILE_IN} $$WAYLAND_INCLUDE_DIR > ${QMAKE_FILE_OUT}
|
|
silent:qtwayland_client_header.commands = @echo QtWayland client header ${QMAKE_FILE_IN} && $$qtwayland_client_header.commands
|
|
QMAKE_EXTRA_COMPILERS += qtwayland_client_header
|
|
|
|
qtwayland_client_code.name = qtwayland ${QMAKE_FILE_BASE}
|
|
qtwayland_client_code.input = WAYLANDCLIENTSOURCES WAYLANDCLIENTSOURCES_SYSTEM
|
|
qtwayland_client_code.variable_out = SOURCES
|
|
qtwayland_client_code.depends += $$QMAKE_QTWAYLANDSCANNER_EXE qwayland-${QMAKE_FILE_BASE}$${first(QMAKE_EXT_H)}
|
|
qtwayland_client_code.output = qwayland-${QMAKE_FILE_BASE}.cpp
|
|
qtwayland_client_code.commands = $$QMAKE_QTWAYLANDSCANNER client-code ${QMAKE_FILE_IN} $$WAYLAND_INCLUDE_DIR > ${QMAKE_FILE_OUT}
|
|
silent:qtwayland_client_code.commands = @echo QtWayland client code ${QMAKE_FILE_IN} && $$qtwayland_client_code.commands
|
|
QMAKE_EXTRA_COMPILERS += qtwayland_client_code
|
|
|
|
qtwayland_server_header.name = qtwayland ${QMAKE_FILE_BASE}
|
|
qtwayland_server_header.input = WAYLANDSERVERSOURCES WAYLANDSERVERSOURCES_SYSTEM
|
|
qtwayland_server_header.variable_out = HEADERS
|
|
qtwayland_server_header.depends += $$QMAKE_QTWAYLANDSCANNER_EXE wayland-${QMAKE_FILE_BASE}-server-protocol$${first(QMAKE_EXT_H)}
|
|
qtwayland_server_header.output = qwayland-server-${QMAKE_FILE_BASE}$${first(QMAKE_EXT_H)}
|
|
qtwayland_server_header.commands = $$QMAKE_QTWAYLANDSCANNER server-header ${QMAKE_FILE_IN} $$WAYLAND_INCLUDE_DIR > ${QMAKE_FILE_OUT}
|
|
silent:qtwayland_server_header.commands = @echo QtWayland server header ${QMAKE_FILE_IN} && $$qtwayland_server_header.commands
|
|
QMAKE_EXTRA_COMPILERS += qtwayland_server_header
|
|
|
|
qtwayland_server_code.name = qtwayland ${QMAKE_FILE_BASE}
|
|
qtwayland_server_code.input = WAYLANDSERVERSOURCES WAYLANDSERVERSOURCES_SYSTEM
|
|
qtwayland_server_code.variable_out = SOURCES
|
|
qtwayland_server_code.depends += $$QMAKE_QTWAYLANDSCANNER_EXE qwayland-server-${QMAKE_FILE_BASE}$${first(QMAKE_EXT_H)}
|
|
qtwayland_server_code.output = qwayland-server-${QMAKE_FILE_BASE}.cpp
|
|
qtwayland_server_code.commands = $$QMAKE_QTWAYLANDSCANNER server-code ${QMAKE_FILE_IN} $$WAYLAND_INCLUDE_DIR > ${QMAKE_FILE_OUT}
|
|
silent:qtwayland_server_code.commands = @echo QtWayland server code ${QMAKE_FILE_IN} && $$qtwayland_server_code.commands
|
|
QMAKE_EXTRA_COMPILERS += qtwayland_server_code
|