vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
44 lines
1.7 KiB
Plaintext
44 lines
1.7 KiB
Plaintext
# This file is loaded as one of the last things by all qmakespecs.
|
|
|
|
QMAKE_QT_CONFIG = $$[QT_HOST_DATA/get]/mkspecs/qconfig.pri
|
|
!exists($$QMAKE_QT_CONFIG)|!include($$QMAKE_QT_CONFIG, "", true) {
|
|
debug(1, "Cannot load qconfig.pri!")
|
|
} else {
|
|
debug(1, "Loaded .qconfig.pri from ($$QMAKE_QT_CONFIG)")
|
|
dirs = $$(QMAKEMODULES)
|
|
QMAKE_MODULE_PATH = $$split(dirs, $$DIRLIST_SEPARATOR)
|
|
QMAKE_MODULE_PATH += $$QMAKEMODULES
|
|
dirs = $$[QMAKEMODULES]
|
|
QMAKE_MODULE_PATH += $$split(dirs, $$DIRLIST_SEPARATOR)
|
|
dirs = $$[QMAKE_MKSPECS]
|
|
dirs = $$split(dirs, $$DIRLIST_SEPARATOR)
|
|
QMAKE_MODULE_PATH += $$replace(dirs, \$, /modules)
|
|
unset(dirs)
|
|
QMAKE_MODULE_PATH = $$unique(QMAKE_MODULE_PATH)
|
|
QMAKE_MODULE_PATH = $$reverse(QMAKE_MODULE_PATH)
|
|
for(dir, QMAKE_MODULE_PATH) {
|
|
debug(1, "Loading modules from $${dir}")
|
|
mods = $$files($$dir/qt_*.pri)
|
|
for (mod, mods) {
|
|
# For installed Qt these paths will be common for all modules.
|
|
# For uninstalled prefix builds these will vary per module, via the
|
|
# forwarding module pri files. Keep qt_module_pris.prf in sync with this!
|
|
QT_MODULE_INCLUDE_BASE = $$[QT_INSTALL_HEADERS]
|
|
QT_MODULE_LIB_BASE = $$[QT_INSTALL_LIBS]
|
|
QT_MODULE_HOST_LIB_BASE = $$[QT_HOST_LIBS]
|
|
QT_MODULE_HOST_LIBEXEC_BASE = $$[QT_HOST_LIBEXECS]
|
|
QT_MODULE_BIN_BASE = $$[QT_INSTALL_BINS]
|
|
include($$mod)
|
|
}
|
|
unset(mods)
|
|
}
|
|
QT_MODULES = $$unique(QT_MODULES) # In case modules appear in multiple places
|
|
unset(QT_MODULE_INCLUDE_BASE)
|
|
unset(QT_MODULE_LIB_BASE)
|
|
unset(QT_MODULE_HOST_LIB_BASE)
|
|
unset(QT_MODULE_HOST_LIBEXEC_BASE)
|
|
unset(QT_MODULE_BIN_BASE)
|
|
}
|
|
|
|
load(qt_functions)
|