vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
39 lines
1.3 KiB
Plaintext
39 lines
1.3 KiB
Plaintext
suffix =
|
|
for(ever) {
|
|
CC_USES =
|
|
LD_USES =
|
|
for (use, QMAKE_USE$${suffix}) {
|
|
use = $$split(use, /)
|
|
name = $$take_first(use)
|
|
nu = $$upper($$replace(name, -, _))
|
|
!contains(use, linkonly): CC_USES += $$nu
|
|
!contains(use, nolink): LD_USES += $$nu
|
|
}
|
|
CC_USES = $$resolve_depends(CC_USES, QMAKE_DEPENDS_, _CC)
|
|
for (nu, CC_USES) {
|
|
!defined(QMAKE_LIBS_$$nu, var): \
|
|
error("Library '$$lower($$replace(nu, _, -))' is not defined.")
|
|
|
|
DEFINES += $$eval(QMAKE_DEFINES_$${nu})
|
|
INCLUDEPATH += $$eval(QMAKE_INCDIR_$${nu})
|
|
}
|
|
LD_USES = $$resolve_depends(LD_USES, QMAKE_DEPENDS_, _LD)
|
|
for (nu, LD_USES) {
|
|
!defined(QMAKE_LIBS_$$nu, var): \
|
|
error("Library '$$lower($$replace(nu, _, -))' is not defined.")
|
|
|
|
QMAKE_LIBDIR += $$eval(QMAKE_LIBDIR_$$nu)
|
|
|
|
android {
|
|
ABI_LIBS = $$eval(QMAKE_LIBS_$${nu}_$${QT_ARCH})
|
|
isEmpty(ABI_LIBS): ABI_LIBS = $$eval(QMAKE_LIBS_$${nu})
|
|
LIBS$${suffix} += $$ABI_LIBS
|
|
} else: debug: \
|
|
LIBS$${suffix} += $$eval(QMAKE_LIBS_$${nu}_DEBUG) $$eval(QMAKE_LIBS_$$nu)
|
|
else: \
|
|
LIBS$${suffix} += $$eval(QMAKE_LIBS_$${nu}_RELEASE) $$eval(QMAKE_LIBS_$$nu)
|
|
}
|
|
!isEmpty(suffix): break()
|
|
suffix = "_PRIVATE"
|
|
}
|