vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
54 lines
1.9 KiB
Plaintext
54 lines
1.9 KiB
Plaintext
isEmpty(COPIES): return()
|
|
contains(TEMPLATE, .*subdirs): error("COPIES does not work with TEMPLATE=subdirs")
|
|
|
|
build_pass:build_all:!isEqual(BUILD_PASS, $$first(BUILDS)) {
|
|
# Avoid that multiple build passes race with each other.
|
|
# This will fail to copy anything if the user explicitly invokes
|
|
# only the non-primary build. This is unfixable, as at qmake time
|
|
# we cannot possibly know how make will be invoked, yet we must
|
|
# predict it here.
|
|
return()
|
|
}
|
|
|
|
defineReplace(qtStripProPwd) {
|
|
return($$relative_path($$1, $$_PRO_FILE_PWD_))
|
|
}
|
|
|
|
for (cp, COPIES) {
|
|
isEmpty($${cp}.files): next()
|
|
pfx = copy_$${cp}
|
|
notdir = false
|
|
dir = false
|
|
for (f, $${cp}.files) {
|
|
fil = $$absolute_path($$f, $$_PRO_FILE_PWD_)
|
|
tfiles = $$files($$fil/*)
|
|
isEmpty(tfiles): \
|
|
notdir = true
|
|
else: \
|
|
dir = true
|
|
$${pfx}.files += $$fil
|
|
}
|
|
$$dir:$$notdir: \
|
|
error("COPIES entry $$cp lists both files and directories.")
|
|
path = $$eval($${cp}.path)
|
|
isEmpty(path): error("COPIES entry $$cp defines no .path")
|
|
base = $$eval($${cp}.base)
|
|
isEmpty(base) {
|
|
$${pfx}.output = $$path/${QMAKE_FILE_IN_NAME}
|
|
} else: isEqual(base, $$_PRO_FILE_PWD_) {
|
|
$${pfx}.output = $$path/${QMAKE_FUNC_FILE_IN_qtStripProPwd}
|
|
} else {
|
|
eval(defineReplace(qtStripSrcDir_$$cp) { \
|
|
return(\$\$relative_path(\$\$1, $$val_escape(base))) \
|
|
})
|
|
$${pfx}.output = $$path/${QMAKE_FUNC_FILE_IN_qtStripSrcDir_$$cp}
|
|
}
|
|
$${pfx}.input = $${pfx}.files
|
|
contains(TEMPLATE, "vc.*"): copycommand = $$QMAKE_QMAKE -install qinstall
|
|
else: copycommand = $(QINSTALL)
|
|
$${pfx}.commands = $$copycommand ${QMAKE_FILE_IN} ${QMAKE_FILE_OUT}
|
|
$${pfx}.name = COPY ${QMAKE_FILE_IN}
|
|
$${pfx}.CONFIG = no_link no_clean target_predeps
|
|
QMAKE_EXTRA_COMPILERS += $${pfx}
|
|
}
|