vasilito
7686729069
Extract protocol-agnostic FenceTimeline from Intel to shared src/drivers/fence.rs — atomic-based fence tracking suitable for Intel, VIRGL, and AMD drivers. Extract protocol-agnostic SyncobjManager from Intel to shared src/drivers/syncobj.rs — syncobj create/destroy/signal/reset/ wait/query and sync_file fd export/import. Wire both into VirtioDriver: - Add FenceTimeline + SyncobjManager fields - Implement all 5 GpuDriver syncobj trait methods (create, destroy, wait, export_fd, import_fd) - Track fence seqnos in virgl_submit_3d (allocate before submit, signal after completion) Intel fence.rs and syncobj.rs converted to thin re-export modules pointing at shared sources — no behavioral change for Intel driver. This gives Mesa VIRGL userspace the standard DRM syncobj API for GPU/compositor synchronization.
63 lines
1.9 KiB
Plaintext
63 lines
1.9 KiB
Plaintext
# vsnprintf.m4 serial 7
|
|
dnl Copyright (C) 2002-2004, 2007-2023 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl Libintl 0.17 will replace vsnprintf only if it does not support %1$s,
|
|
dnl but defers to any gnulib vsnprintf replacements. Therefore, gnulib
|
|
dnl must guarantee that the decision for replacing vsnprintf is a superset
|
|
dnl of the reasons checked by libintl.
|
|
AC_DEFUN([gl_FUNC_VSNPRINTF],
|
|
[
|
|
AC_REQUIRE([gl_STDIO_H_DEFAULTS])
|
|
gl_cv_func_vsnprintf_usable=no
|
|
AC_CHECK_FUNCS([vsnprintf])
|
|
if test $ac_cv_func_vsnprintf = yes; then
|
|
gl_SNPRINTF_SIZE1
|
|
case "$gl_cv_func_snprintf_size1" in
|
|
*yes)
|
|
gl_SNPRINTF_RETVAL_C99
|
|
case "$gl_cv_func_snprintf_retval_c99" in
|
|
*yes)
|
|
gl_PRINTF_POSITIONS
|
|
case "$gl_cv_func_printf_positions" in
|
|
*yes)
|
|
gl_cv_func_vsnprintf_usable=yes
|
|
;;
|
|
esac
|
|
;;
|
|
esac
|
|
;;
|
|
esac
|
|
fi
|
|
if test $gl_cv_func_vsnprintf_usable = no; then
|
|
gl_REPLACE_VSNPRINTF
|
|
fi
|
|
AC_CHECK_DECLS_ONCE([vsnprintf])
|
|
if test $ac_cv_have_decl_vsnprintf = no; then
|
|
HAVE_DECL_VSNPRINTF=0
|
|
fi
|
|
])
|
|
|
|
AC_DEFUN([gl_REPLACE_VSNPRINTF],
|
|
[
|
|
AC_REQUIRE([gl_STDIO_H_DEFAULTS])
|
|
AC_LIBOBJ([vsnprintf])
|
|
if test $ac_cv_func_vsnprintf = yes; then
|
|
REPLACE_VSNPRINTF=1
|
|
else
|
|
AC_CHECK_DECLS_ONCE([vsnprintf])
|
|
if test $ac_cv_have_decl_vsnprintf = yes; then
|
|
dnl If the function is declared but does not appear to exist, it may be
|
|
dnl defined as an inline function. In order to avoid a conflict, we have
|
|
dnl to define rpl_vsnprintf, not vsnprintf.
|
|
REPLACE_VSNPRINTF=1
|
|
fi
|
|
fi
|
|
gl_PREREQ_VSNPRINTF
|
|
])
|
|
|
|
# Prerequisites of lib/vsnprintf.c.
|
|
AC_DEFUN([gl_PREREQ_VSNPRINTF], [:])
|