vasilito
ff4ff35918
Red Bear OS is a full fork. All sources must be available from git clone with zero network access. Removed gitignore rules that excluded fetched source trees under recipes/*/source/, local/recipes/kde/*/source/, local/recipes/qt/*/source/, and vendor source trees. Build artifacts (target/, build/, source.tar, *.o, *.so) remain excluded. 127291 files added — kernel, relibc, base, bootloader, pkgar, all KDE/Qt frameworks, mesa, wayland, DRM drivers, and every other recipe source.
28 lines
886 B
Plaintext
28 lines
886 B
Plaintext
#compdef add-zsh-hook
|
|
|
|
_add-zsh-hook_hooks() {
|
|
local expl
|
|
if (( $+opt_args[-d] )); then
|
|
_wanted functions expl "installed hook" compadd -a - "$line[1]_functions" && return 0
|
|
else
|
|
_functions && return 0
|
|
fi
|
|
return 1
|
|
}
|
|
|
|
_add-zsh-hook() {
|
|
local context state state_descr line
|
|
typeset -A opt_args
|
|
_arguments -s -w -S : \
|
|
"(-d -D -U -z -k)-L[output in form of 'typeset' commands]" \
|
|
'(-L -D -U -z -k)-d[remove HOOK from the array]' \
|
|
'(-L -d -U -z -k)-D[interpret HOOK as pattern to remove from the array]' \
|
|
'(-L -d -D)-U[suppress alias expansion for functions]' \
|
|
'(-L -d -D -k)-z[mark function for zsh-style autoloading]' \
|
|
'(-L -d -D -z)-k[mark function for ksh-style autoloading]' \
|
|
':hook class:(chpwd precmd preexec periodic zshaddhistory zshexit zsh_directory_name)' \
|
|
':hook function:_add-zsh-hook_hooks'
|
|
}
|
|
|
|
_add-zsh-hook "$@"
|