vasilito
ff4ff35918
Red Bear OS is a full fork. All sources must be available from git clone with zero network access. Removed gitignore rules that excluded fetched source trees under recipes/*/source/, local/recipes/kde/*/source/, local/recipes/qt/*/source/, and vendor source trees. Build artifacts (target/, build/, source.tar, *.o, *.so) remain excluded. 127291 files added — kernel, relibc, base, bootloader, pkgar, all KDE/Qt frameworks, mesa, wayland, DRM drivers, and every other recipe source.
27 lines
793 B
Plaintext
27 lines
793 B
Plaintext
#compdef wc gwc
|
|
|
|
local args
|
|
|
|
args=(
|
|
'(-c --bytes)'{-c,--bytes}'[print byte counts]'
|
|
'(-C -m --chars)'{-m,--chars}'[print character counts]'
|
|
'(-w --words)'{-w,--words}'[print word counts]'
|
|
'(-l --lines)'{-l,--lines}'[print line counts]'
|
|
)
|
|
|
|
if _pick_variant gnu=GNU unix --version; then
|
|
args+=(
|
|
'(*)--files0-from=[read NUL-terminated file list from specified file]:file:_files'
|
|
'(-L --max-line-length)'{-L,--max-line-length}'[print longest line lengths]'
|
|
)
|
|
else
|
|
args=( -A "-*" "${(@)args:#(|\(*\))(|\*)--*}" )
|
|
case $OSTYPE in
|
|
freebsd*|netbsd*) args+=( '-L[print longest line lengths]' ) ;;
|
|
openbsd*) args+=( '-h[human readable: use unit suffixes]' ) ;;
|
|
solaris*) args+=( ${${(M)args:#*-m\[*}//-m\[/-C\[} ) ;;
|
|
esac
|
|
fi
|
|
|
|
_arguments -s -S $args '*:file:_files'
|