vasilito
ff4ff35918
Red Bear OS is a full fork. All sources must be available from git clone with zero network access. Removed gitignore rules that excluded fetched source trees under recipes/*/source/, local/recipes/kde/*/source/, local/recipes/qt/*/source/, and vendor source trees. Build artifacts (target/, build/, source.tar, *.o, *.so) remain excluded. 127291 files added — kernel, relibc, base, bootloader, pkgar, all KDE/Qt frameworks, mesa, wayland, DRM drivers, and every other recipe source.
40 lines
1.1 KiB
Plaintext
40 lines
1.1 KiB
Plaintext
#compdef scl
|
|
|
|
local curcontext="$curcontext" dashes ret=1
|
|
local -a state line force alts cmd
|
|
|
|
[[ $words[2] = deregister ]] &&
|
|
force=( '--force[deregister even SCL installed as packages]' )
|
|
|
|
_arguments -C $force \
|
|
'(- 1)'{-l,--list}'[list installed software collections or packages within a collection]' \
|
|
'(-l --list)1:action:(enable run load unload list-collections list-enabled list-packages man register deregister)' \
|
|
'(- *)--help' \
|
|
'(-)*:collections:->collections' && ret=0
|
|
|
|
if [[ -n $state ]]; then
|
|
(( $#line > 1 )) && curcontext="${curcontext%:*}-$line[1]:"
|
|
if [[ $line[1] = register ]]; then
|
|
_directories -P / -W /
|
|
return
|
|
fi
|
|
if (( ${dashes:=$words[(I)--]} )); then
|
|
shift dashes words
|
|
(( CURRENT -= dashes ))
|
|
_normal
|
|
return
|
|
fi
|
|
if [[ $CURRENT -gt 3 && $words[CURRENT] = - ]]; then
|
|
compadd - --
|
|
return
|
|
fi
|
|
[[ $line[1] = enable && $CURRENT -gt 3 ]] &&
|
|
cmd='command:command:_cmdstring'
|
|
|
|
_alternative 'collections:collection:compadd
|
|
$(_call_program collections "${words[1]} list-collections || ${words[1]} -l")' \
|
|
$cmd && ret=0
|
|
fi
|
|
|
|
return ret
|