vasilito
ff4ff35918
Red Bear OS is a full fork. All sources must be available from git clone with zero network access. Removed gitignore rules that excluded fetched source trees under recipes/*/source/, local/recipes/kde/*/source/, local/recipes/qt/*/source/, and vendor source trees. Build artifacts (target/, build/, source.tar, *.o, *.so) remain excluded. 127291 files added — kernel, relibc, base, bootloader, pkgar, all KDE/Qt frameworks, mesa, wayland, DRM drivers, and every other recipe source.
30 lines
991 B
Plaintext
30 lines
991 B
Plaintext
#compdef mdfind
|
|
|
|
local ret=1
|
|
local -a context line state state_descr tmp
|
|
local -A opt_args val_args
|
|
|
|
_arguments -s -S : \
|
|
'(-count)-0[separate result paths by NUL]' \
|
|
'(-0)-count[display count of results instead of paths]' \
|
|
'(-literal)-interpret[interpret query as if entered in Spotlight search field]' \
|
|
'(-interpret)-literal[interpret query as literal query string]' \
|
|
'-live[provide live updates to query results]' \
|
|
'-onlyin[limit search to specified directory]: :_directories' \
|
|
'(: -s)*-name[search for files with names matching specified string]:file name string' \
|
|
'-reprint[reprint -live results on update]' \
|
|
'(: -name)-s[show contents of specified smart folder]: :->smart-folders' \
|
|
'(-s -name)1: :_guard "^-*" "query"' \
|
|
&& ret=0
|
|
|
|
[[ $state == smart-folders ]] && {
|
|
tmp=( "$HOME/Library/Saved Searches/"*.savedSearch(-.N:r:t) )
|
|
if (( $#tmp )); then
|
|
_values 'smart folder' $tmp && ret=0
|
|
else
|
|
_message 'smart folder' && ret=0
|
|
fi
|
|
}
|
|
|
|
return ret
|