vasilito
cee25393d8
- Fix P15-8-init-cycle-detection.patch: replace visiting+error with seen+silent-skip to eliminate 11 false-positive 'dependency cycle detected' errors on shared deps - Fix P0-daemon-fix-init-notify-unwrap.patch: remove eprintln! for missing INIT_NOTIFY (expected for oneshot_async services, ~7 daemons affected) - Fix driver-manager hotplug loop: add PERMANENTLY_SKIPPED static set shared between hotplug handler and DriverConfig::probe() to stop infinite re-probing of Fatal/NotSupported/deferred-exhausted device+driver pairs (e.g. ided) - Fix driver-manager log_timeline: suppress repeated EPIPE/ENOENT errors with AtomicI32 dedup and AtomicBool one-shot guards for boot timeline JSON - Add driver-manager SIGTERM handler, ACPI bus registration, --status mode, driver reap loop, graceful shutdown, and reduced deferred retries (30→3)
51 lines
1.4 KiB
Plaintext
51 lines
1.4 KiB
Plaintext
dnl
|
|
dnl Subshell support.
|
|
dnl
|
|
AC_DEFUN([mc_SUBSHELL], [
|
|
|
|
AC_MSG_CHECKING([for subshell support])
|
|
AC_ARG_WITH(subshell,
|
|
[ --with-subshell Compile in concurrent subshell @<:@yes@:>@
|
|
--with-subshell=optional Don't run concurrent shell by default @<:@no@:>@],
|
|
[
|
|
case "x$withval" in
|
|
xyes)
|
|
result="yes"
|
|
;;
|
|
xoptional)
|
|
result="optional"
|
|
;;
|
|
*)
|
|
result="no"
|
|
;;
|
|
esac
|
|
],
|
|
[
|
|
dnl Default: enable the subshell support
|
|
result="yes"
|
|
])
|
|
|
|
AC_MSG_RESULT([$result])
|
|
|
|
if test "x$result" != xno; then
|
|
AC_DEFINE(ENABLE_SUBSHELL, 1, [Define to enable subshell support])
|
|
|
|
dnl openpty() can simplify opening of master/slave devices for subshell
|
|
AC_CHECK_HEADERS([pty.h libutil.h util.h])
|
|
AC_CHECK_FUNCS(openpty,,
|
|
AC_CHECK_LIB(util,openpty,
|
|
[AC_DEFINE(HAVE_OPENPTY)
|
|
LIBS="$LIBS -lutil"]
|
|
)
|
|
)
|
|
|
|
if test "x$result" = xoptional; then
|
|
AC_DEFINE(SUBSHELL_OPTIONAL, 1, [Define to make subshell support optional])
|
|
fi
|
|
fi
|
|
|
|
subshell="$result"
|
|
|
|
AM_CONDITIONAL(ENABLE_SUBSHELL, [test "x$result" != xno])
|
|
])
|