vasilito
ff4ff35918
Red Bear OS is a full fork. All sources must be available from git clone with zero network access. Removed gitignore rules that excluded fetched source trees under recipes/*/source/, local/recipes/kde/*/source/, local/recipes/qt/*/source/, and vendor source trees. Build artifacts (target/, build/, source.tar, *.o, *.so) remain excluded. 127291 files added — kernel, relibc, base, bootloader, pkgar, all KDE/Qt frameworks, mesa, wayland, DRM drivers, and every other recipe source.
44 lines
1.3 KiB
CMake
44 lines
1.3 KiB
CMake
# Copyright (C) 2022 The Qt Company Ltd.
|
|
# SPDX-License-Identifier: BSD-3-Clause
|
|
|
|
if(TARGET WrapSystemMd4c::WrapSystemMd4c)
|
|
set(WrapSystemMd4c_FOUND TRUE)
|
|
return()
|
|
endif()
|
|
set(WrapSystemMd4c_REQUIRED_VARS __md4c_found)
|
|
|
|
find_package(md4c ${${CMAKE_FIND_PACKAGE_NAME}_FIND_VERSION} QUIET)
|
|
|
|
set(__md4c_target_name "md4c::md4c")
|
|
|
|
if(md4c_FOUND)
|
|
set(__md4c_found TRUE)
|
|
|
|
# md4c provides a md4c::md4c target but
|
|
# older versions create a md4c target without
|
|
# namespace. If we find the old variant create
|
|
# a namespaced target out of the md4c target.
|
|
if(TARGET md4c AND NOT TARGET ${__md4c_target_name})
|
|
add_library(${__md4c_target_name} INTERFACE IMPORTED)
|
|
target_link_libraries(${__md4c_target_name} INTERFACE md4c)
|
|
endif()
|
|
|
|
if(md4c_VERSION)
|
|
set(WrapSystemMd4c_VERSION "${md4c_VERSION}")
|
|
endif()
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(WrapSystemMd4c
|
|
REQUIRED_VARS ${WrapSystemMd4c_REQUIRED_VARS}
|
|
VERSION_VAR WrapSystemMd4c_VERSION)
|
|
|
|
if(WrapSystemMd4c_FOUND)
|
|
add_library(WrapSystemMd4c::WrapSystemMd4c INTERFACE IMPORTED)
|
|
target_link_libraries(WrapSystemMd4c::WrapSystemMd4c
|
|
INTERFACE "${__md4c_target_name}")
|
|
endif()
|
|
|
|
unset(__md4c_found)
|
|
unset(__md4c_target_name)
|