vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
157 lines
4.9 KiB
Plaintext
157 lines
4.9 KiB
Plaintext
#
|
|
# qmake configuration for Microsoft Visual Studio C/C++ Compiler
|
|
# This file is used by win32-msvc
|
|
#
|
|
|
|
#
|
|
# Version-specific changes
|
|
#
|
|
|
|
isEmpty(QMAKE_MSC_VER): error("msvc-version.conf loaded but QMAKE_MSC_VER isn't set")
|
|
|
|
MSVC_VER = 8.0
|
|
COMPAT_MKSPEC = win32-msvc2005
|
|
|
|
greaterThan(QMAKE_MSC_VER, 1499) {
|
|
# Visual Studio 2008 (9.0) / Visual C++ 15.0 and up
|
|
MSVC_VER = 9.0
|
|
MSVC_TOOLSET_VER = 90
|
|
COMPAT_MKSPEC = win32-msvc2008
|
|
QMAKE_CFLAGS_MP = -MP
|
|
QMAKE_CXXFLAGS_MP = $$QMAKE_CFLAGS_MP
|
|
}
|
|
|
|
greaterThan(QMAKE_MSC_VER, 1599) {
|
|
# Visual Studio 2010 (10.0) / Visual C++ 16.0 and up
|
|
MSVC_VER = 10.0
|
|
MSVC_TOOLSET_VER = 100
|
|
COMPAT_MKSPEC = win32-msvc2010
|
|
MAKEFILE_GENERATOR = MSBUILD
|
|
|
|
QMAKE_CFLAGS_AVX = -arch:AVX
|
|
QMAKE_CFLAGS_AVX2 = -arch:AVX
|
|
|
|
VCPROJ_EXTENSION = .vcxproj
|
|
}
|
|
|
|
greaterThan(QMAKE_MSC_VER, 1699) {
|
|
# Visual Studio 2012 (11.0) / Visual C++ 17.0 and up
|
|
MSVC_VER = 11.0
|
|
MSVC_TOOLSET_VER = 110
|
|
COMPAT_MKSPEC = win32-msvc2012
|
|
QMAKE_CXXFLAGS_EXCEPTIONS_OFF = /wd4530 /wd4577
|
|
QT_CONFIG += c++11
|
|
CONFIG += c++11
|
|
}
|
|
|
|
greaterThan(QMAKE_MSC_VER, 1799) {
|
|
# Visual Studio 2013 (12.0) / Visual C++ 18.0 and up
|
|
MSVC_VER = 12.0
|
|
MSVC_TOOLSET_VER = 120
|
|
COMPAT_MKSPEC = win32-msvc2013
|
|
QMAKE_CFLAGS += -FS
|
|
QMAKE_CXXFLAGS += -FS -Zc:rvalueCast -Zc:inline
|
|
|
|
QMAKE_CFLAGS_F16C = -arch:AVX
|
|
QMAKE_CFLAGS_RDRND =
|
|
QMAKE_CFLAGS_RDSEED =
|
|
|
|
equals(QMAKE_MSC_VER, 1800) {
|
|
QMAKE_CFLAGS_RELEASE += -Zc:strictStrings
|
|
QMAKE_CFLAGS_RELEASE_WITH_DEBUGINFO += -Zc:strictStrings
|
|
QMAKE_CXXFLAGS_RELEASE += -Zc:strictStrings
|
|
QMAKE_CXXFLAGS_RELEASE_WITH_DEBUGINFO += -Zc:strictStrings
|
|
}
|
|
}
|
|
|
|
greaterThan(QMAKE_MSC_VER, 1899) {
|
|
# Visual Studio 2015 (14.0) / Visual C++ 19.0 and up
|
|
MSVC_VER = 14.0
|
|
MSVC_TOOLSET_VER = 140
|
|
COMPAT_MKSPEC = win32-msvc2015
|
|
QMAKE_CFLAGS += -Zc:strictStrings
|
|
QMAKE_CFLAGS_WARN_ON += -w44456 -w44457 -w44458
|
|
QMAKE_CFLAGS_AVX2 = -arch:AVX2
|
|
QMAKE_CXXFLAGS += -Zc:strictStrings -Zc:throwingNew
|
|
QMAKE_CXXFLAGS_WARN_ON += -w44456 -w44457 -w44458 -wd4577 -wd4467
|
|
|
|
# -utf-8 compiler option for Visual Studio 2015 Update 2
|
|
greaterThan(QMAKE_MSC_FULL_VER, 190023918): QMAKE_CFLAGS_UTF8_SOURCE = -utf-8
|
|
}
|
|
|
|
greaterThan(QMAKE_MSC_VER, 1909) {
|
|
# Visual Studio 2017 (15.0) / Visual C++ 19.10 and up
|
|
MSVC_VER = 15.0
|
|
MSVC_TOOLSET_VER = 141
|
|
COMPAT_MKSPEC = win32-msvc2017
|
|
QMAKE_CXXFLAGS += -permissive-
|
|
|
|
# Only Visual Studio 2017 version 15.3 / Visual C++ 19.11 & up have support
|
|
# for AVX-512. We enable the switches anyway and let configure check if they
|
|
# work.
|
|
QMAKE_CFLAGS_AVX512F = -arch:AVX512
|
|
QMAKE_CFLAGS_AVX512ER = -arch:AVX512
|
|
QMAKE_CFLAGS_AVX512CD = -arch:AVX512
|
|
QMAKE_CFLAGS_AVX512PF = -arch:AVX512
|
|
QMAKE_CFLAGS_AVX512DQ = -arch:AVX512
|
|
QMAKE_CFLAGS_AVX512BW = -arch:AVX512
|
|
QMAKE_CFLAGS_AVX512VL = -arch:AVX512
|
|
QMAKE_CFLAGS_AVX512IFMA = -arch:AVX512
|
|
QMAKE_CFLAGS_AVX512VBMI = -arch:AVX512
|
|
|
|
# MSVC partially supports the following, but '__cplusplus' definition is set
|
|
# as for C++98 until MSVC fully conforms with C++14, see
|
|
# https://developercommunity.visualstudio.com/content/problem/139261/msvc-incorrectly-defines-cplusplus.html
|
|
# Support became available in MSVC 2017 15.7:
|
|
greaterThan(QMAKE_MSC_VER, 1913) {
|
|
QMAKE_CXXFLAGS += -Zc:__cplusplus
|
|
QMAKE_CXXFLAGS_CXX14 = -std:c++14
|
|
QMAKE_CXXFLAGS_CXX1Z = -std:c++17
|
|
}
|
|
}
|
|
|
|
greaterThan(QMAKE_MSC_VER, 1910) {
|
|
# No compat spec past MSVC 2017
|
|
COMPAT_MKSPEC =
|
|
}
|
|
|
|
greaterThan(QMAKE_MSC_VER, 1919) {
|
|
# Visual Studio 2019 (16.0) / Visual C++ 19.20 and up
|
|
MSVC_VER = 16.0
|
|
MSVC_TOOLSET_VER = 142
|
|
QMAKE_CXXFLAGS_CXX2A = -std:c++latest
|
|
QMAKE_CXXFLAGS_CXX2B = -std:c++latest
|
|
QMAKE_CXXFLAGS_CXX2C = -std:c++latest
|
|
|
|
QMAKE_CXXFLAGS += -Zc:externConstexpr
|
|
}
|
|
|
|
greaterThan(QMAKE_MSC_VER, 1927) {
|
|
# Visual Studio 2019 (16.8 or 16.9) / Visual C++ 19.28 and up
|
|
MSVC_VER = 16.8
|
|
QMAKE_CFLAGS_C11 = /std:c11
|
|
QMAKE_CFLAGS_C17 = /std:c17
|
|
}
|
|
|
|
greaterThan(QMAKE_MSC_VER, 1928) {
|
|
# Visual Studio 2019 (16.10 or 16.11) / Visual C++ 19.29 and up
|
|
MSVC_VER = 16.10
|
|
|
|
# -std:c++20 compiler option for Visual Studio 2019 16.11.0 and up
|
|
greaterThan(QMAKE_MSC_FULL_VER, 192930132): QMAKE_CXXFLAGS_CXX2A = -std:c++20
|
|
}
|
|
|
|
greaterThan(QMAKE_MSC_VER, 1929) {
|
|
# Visual Studio 2022 (17.0) / Visual C++ 19.30 and up
|
|
MSVC_VER = 17.0
|
|
MSVC_TOOLSET_VER = 143
|
|
}
|
|
|
|
greaterThan(QMAKE_MSC_VER, 1949) {
|
|
# Visual Studio 2026 (18.0) / Visual C++ 19.50 and up
|
|
MSVC_VER = 18.0
|
|
MSVC_TOOLSET_VER = 145
|
|
}
|
|
|
|
!isEmpty(COMPAT_MKSPEC):!$$COMPAT_MKSPEC: CONFIG += $$COMPAT_MKSPEC
|