vasilito
f31522130f
Build system (5 gaps hardened): - COOKBOOK_OFFLINE defaults to true (fork-mode) - normalize_patch handles diff -ruN format - New 'repo validate-patches' command (25/25 relibc patches) - 14 patched Qt/Wayland/display recipes added to protected list - relibc archive regenerated with current patch chain Boot fixes (fixable): - Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset) - D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped) - redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped) - daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch) - udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async) - relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs - greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait) - greeter-ui: built and linked (header guard unification, sem_compat stubs removed) - mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps - greeter config: removed stale keymapd dependency from display/greeter services - prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified Unfixable (diagnosed, upstream): - i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort - kded6/greeter-ui: page fault 0x8 — Qt library null deref - Thread panics fd != -1 — Rust std library on Redox - DHCP timeout / eth0 MAC — QEMU user-mode networking - hwrngd/thermald — no hardware RNG/thermal in VM - live preload allocation — BIOS memory fragmentation, continues on demand
58 lines
1.3 KiB
CMake
58 lines
1.3 KiB
CMake
# Copyright (C) 2022 The Qt Company Ltd.
|
|
# SPDX-License-Identifier: BSD-3-Clause
|
|
|
|
# We can't create the same interface imported target multiple times, CMake will complain if we do
|
|
# that. This can happen if the find_package call is done in multiple different subdirectories.
|
|
if(TARGET WrapRt::WrapRt)
|
|
set(WrapRt_FOUND ON)
|
|
return()
|
|
endif()
|
|
|
|
set(WrapRt_FOUND OFF)
|
|
|
|
include(CheckCXXSourceCompiles)
|
|
include(CMakePushCheckState)
|
|
|
|
find_library(LIBRT rt)
|
|
|
|
cmake_push_check_state()
|
|
if(LIBRT)
|
|
list(APPEND CMAKE_REQUIRED_LIBRARIES "${LIBRT}")
|
|
endif()
|
|
|
|
check_cxx_source_compiles("
|
|
#include <time.h>
|
|
#include <unistd.h>
|
|
|
|
int main(int, char **) {
|
|
struct timespec ts;
|
|
clock_gettime(CLOCK_REALTIME, &ts);
|
|
return 0;
|
|
}
|
|
" HAVE_GETTIME)
|
|
|
|
check_cxx_source_compiles("
|
|
#include <sys/types.h>
|
|
#include <sys/mman.h>
|
|
#include <fcntl.h>
|
|
|
|
int main(int, char **) {
|
|
shm_open(\"test\", O_RDWR | O_CREAT | O_EXCL, 0666);
|
|
shm_unlink(\"test\");
|
|
return 0;
|
|
}
|
|
" HAVE_SHM_OPEN_SHM_UNLINK)
|
|
|
|
cmake_pop_check_state()
|
|
|
|
if(HAVE_GETTIME OR HAVE_SHM_OPEN_SHM_UNLINK)
|
|
set(WrapRt_FOUND ON)
|
|
add_library(WrapRt::WrapRt INTERFACE IMPORTED)
|
|
if (LIBRT)
|
|
target_link_libraries(WrapRt::WrapRt INTERFACE "${LIBRT}")
|
|
endif()
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(WrapRt DEFAULT_MSG WrapRt_FOUND)
|