vasilito
facf0c92e0
Red Bear OS is a full fork. All sources must be available from git clone with zero network access. Removed gitignore rules that excluded fetched source trees under recipes/*/source/, local/recipes/kde/*/source/, local/recipes/qt/*/source/, and vendor source trees. Build artifacts (target/, build/, source.tar, *.o, *.so) remain excluded. 127291 files added — kernel, relibc, base, bootloader, pkgar, all KDE/Qt frameworks, mesa, wayland, DRM drivers, and every other recipe source.
52 lines
1.2 KiB
Plaintext
52 lines
1.2 KiB
Plaintext
# function zfopen {
|
|
# Use zftp params to set parameters for open, rather than sending
|
|
# them straight to open. That way they are stored for a future open
|
|
# command.
|
|
#
|
|
# With option -1 (just this 1ce), don't do that.
|
|
|
|
emulate -L zsh
|
|
|
|
[[ $curcontext = :zf* ]] || local curcontext=:zfopen
|
|
local opt dir opt_1 setparams
|
|
|
|
while getopts :1 opt; do
|
|
[[ $opt = "?" ]] && print "zfopen: bad option: -$OPTARG" >&2 && return 1
|
|
eval "opt_$opt=1"
|
|
done
|
|
(( OPTIND > 1 )) && shift $(( OPTIND - 1 ))
|
|
|
|
# This is where we should try and do same name-lookupage in
|
|
# both .netrc and .ncftp/bookmarks . We could even try saving
|
|
# the info in their for new hosts, like ncftp does.
|
|
|
|
if [[ $1 = */* ]]; then
|
|
1=${1##ftp://}
|
|
dir=${1#*/}
|
|
1=${1%%/*}
|
|
fi
|
|
|
|
if [[ $opt_1 = 1 ]]; then
|
|
zftp open $* || return 1
|
|
if [[ $# = 1 ]]; then
|
|
if ! zftp login; then
|
|
zftp close
|
|
return 1
|
|
fi
|
|
fi
|
|
else
|
|
# set parameters, but only if there was at least a host
|
|
(( $# > 0 )) && zfparams $* && setparams=1
|
|
# now call with no parameters
|
|
if ! zftp open; then
|
|
[[ -n $ZFTP_HOST ]] && zftp close
|
|
[[ -n $setparams ]] && zfparams -
|
|
return 1
|
|
fi
|
|
fi
|
|
|
|
if [[ -n $dir ]]; then
|
|
zfcd $dir
|
|
fi
|
|
# }
|