fix: comprehensive boot warnings and exceptions — fixable silenced, unfixable diagnosed

Build system (5 gaps hardened):
- COOKBOOK_OFFLINE defaults to true (fork-mode)
- normalize_patch handles diff -ruN format
- New 'repo validate-patches' command (25/25 relibc patches)
- 14 patched Qt/Wayland/display recipes added to protected list
- relibc archive regenerated with current patch chain

Boot fixes (fixable):
- Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset)
- D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped)
- redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped)
- daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch)
- udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async)
- relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs
- greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait)
- greeter-ui: built and linked (header guard unification, sem_compat stubs removed)
- mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps
- greeter config: removed stale keymapd dependency from display/greeter services
- prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified

Unfixable (diagnosed, upstream):
- i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort
- kded6/greeter-ui: page fault 0x8 — Qt library null deref
- Thread panics fd != -1 — Rust std library on Redox
- DHCP timeout / eth0 MAC — QEMU user-mode networking
- hwrngd/thermald — no hardware RNG/thermal in VM
- live preload allocation — BIOS memory fragmentation, continues on demand

local/recipes/qt/qtwayland/source/examples/wayland/multi-output/qml/GridScreen.qml

@@ -0,0 +1,57 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+import QtQuick
+import QtQuick.Window
+import QtWayland.Compositor
+import QtWayland.Compositor.XdgShell
+
+WaylandOutput {
+    id: output
+    property alias gridSurfaces: listModel
+
+    sizeFollowsWindow: true
+    window: Window {
+        width: 1024
+        height: 760
+        visible: true
+
+        Image {
+            id: background
+            anchors.fill: parent
+            fillMode: Image.Tile
+            source: "qrc:/images/background.jpg"
+            smooth: true
+            GridView {
+                id: gridView
+                anchors.fill: parent
+                model: ListModel {
+                    id: listModel
+                }
+                interactive: false
+                cellWidth: 200
+                cellHeight: 200
+                delegate: WaylandQuickItem {
+                    id: item
+                    surface: gridSurface
+                    width: gridView.cellWidth
+                    height: gridView.cellHeight
+                    inputEventsEnabled: false
+                    allowDiscardFrontBuffer: true
+                    MouseArea {
+                        anchors.fill: parent
+                        onClicked: item.surface.activated()
+                    }
+                }
+            }
+        }
+    }
+
+    XdgOutputV1 {
+        name: "WL-2"
+        description: "Overview screen"
+        logicalPosition: output.position
+        logicalSize: Qt.size(output.geometry.width / output.scaleFactor,
+                             output.geometry.height / output.scaleFactor)
+    }
+}

local/recipes/qt/qtwayland/source/examples/wayland/multi-output/qml/ShellChrome.qml

@@ -0,0 +1,33 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+import QtQuick
+import QtWayland.Compositor
+
+ShellSurfaceItem {
+    id: rootChrome
+
+    onSurfaceDestroyed: {
+        bufferLocked = true;
+        destroyAnimation.start();
+    }
+
+    SequentialAnimation {
+        id: destroyAnimation
+        ParallelAnimation {
+            NumberAnimation { target: scaleTransform; property: "yScale"; to: 2/height; duration: 150 }
+            NumberAnimation { target: scaleTransform; property: "xScale"; to: 0.4; duration: 150 }
+        }
+        NumberAnimation { target: scaleTransform; property: "xScale"; to: 0; duration: 150 }
+        ScriptAction { script: { rootChrome.destroy(); } }
+    }
+
+    transform: [
+        Scale {
+            id:scaleTransform
+            origin.x: rootChrome.width / 2
+            origin.y: rootChrome.height / 2
+
+        }
+    ]
+}

local/recipes/qt/qtwayland/source/examples/wayland/multi-output/qml/ShellScreen.qml

@@ -0,0 +1,48 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+import QtQuick
+import QtQuick.Window
+import QtWayland.Compositor
+import QtWayland.Compositor.XdgShell
+
+WaylandOutput {
+    id: output
+    property alias surfaceArea: background
+
+    sizeFollowsWindow: true
+    window: Window {
+        width: 1024
+        height: 760
+        visible: true
+
+        WaylandMouseTracker {
+            id: mouseTracker
+            anchors.fill: parent
+
+            windowSystemCursorEnabled: !clientCursor.visible
+            Image {
+                id: background
+                anchors.fill: parent
+                fillMode: Image.Tile
+                source: "qrc:/images/background.jpg"
+                smooth: true
+            }
+            WaylandCursorItem {
+                id: clientCursor
+                x: mouseTracker.mouseX
+                y: mouseTracker.mouseY
+                visible: surface != null && mouseTracker.containsMouse
+                seat : output.compositor.defaultSeat
+            }
+        }
+    }
+
+    XdgOutputV1 {
+        name: "WL-1"
+        description: "Screen with window management"
+        logicalPosition: output.position
+        logicalSize: Qt.size(output.geometry.width / output.scaleFactor,
+                             output.geometry.height / output.scaleFactor)
+    }
+}

local/recipes/qt/qtwayland/source/examples/wayland/multi-output/qml/main.qml

@@ -0,0 +1,65 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+import QtQuick
+import QtWayland.Compositor
+import QtWayland.Compositor.XdgShell
+
+WaylandCompositor {
+    id: comp
+
+    defaultOutput: shellScreen
+    ShellScreen {
+        id: shellScreen
+        compositor: comp
+    }
+
+    GridScreen {
+        id: gridScreen
+        compositor: comp
+    }
+
+    Component {
+        id: chromeComponent
+        ShellChrome {
+        }
+    }
+
+    Component {
+        id: surfaceComponent
+        WaylandSurface {
+            id: surface
+            signal activated()
+            onHasContentChanged: {
+                if (hasContent && !cursorSurface) {
+                    gridScreen.gridSurfaces.append( { "gridSurface" : surface } );
+                } else {
+                    for (var i = 0; i < gridScreen.gridSurfaces.count; i++) {
+                        if (gridScreen.gridSurfaces.get(i).gridSurface === surface) {
+                            gridScreen.gridSurfaces.remove(i,1);
+                            break;
+                        }
+                    }
+                }
+            }
+        }
+    }
+
+    XdgOutputManagerV1 {}
+
+    // ![xdgshell]
+    XdgShell {
+        onToplevelCreated: (toplevel, xdgSurface) => {
+            var item = chromeComponent.createObject(defaultOutput.surfaceArea, { "shellSurface": xdgSurface } );
+            item.surface.activated.connect(item.raise);
+        }
+    }
+    // ![xdgshell]
+
+    // ![onSurfaceRequested]
+    onSurfaceRequested: (client, id, version) => {
+        var surface = surfaceComponent.createObject(comp, { } );
+        surface.initialize(comp, client, id, version);
+    }
+    // ![onSurfaceRequested]
+}