fix: comprehensive boot warnings and exceptions — fixable silenced, unfixable diagnosed

Build system (5 gaps hardened):
- COOKBOOK_OFFLINE defaults to true (fork-mode)
- normalize_patch handles diff -ruN format
- New 'repo validate-patches' command (25/25 relibc patches)
- 14 patched Qt/Wayland/display recipes added to protected list
- relibc archive regenerated with current patch chain

Boot fixes (fixable):
- Full ISO EFI partition: 16 MiB → 1 MiB (matches mini, BIOS hardcoded 2 MiB offset)
- D-Bus system bus: absolute /usr/bin/dbus-daemon path (was skipped)
- redbear-sessiond: absolute /usr/bin/redbear-sessiond path (was skipped)
- daemon framework: silenced spurious INIT_NOTIFY warnings for oneshot_async services (P0-daemon-silence-init-notify.patch)
- udev-shim: demoted INIT_NOTIFY warning to INFO (expected for oneshot_async)
- relibc: comprehensive named semaphores (sem_open/close/unlink) replacing upstream todo!() stubs
- greeterd: Wayland socket timeout 15s → 30s (compositor DRM wait)
- greeter-ui: built and linked (header guard unification, sem_compat stubs removed)
- mc: un-ignored in both configs, fixed glib/libiconv/pcre2 transitive deps
- greeter config: removed stale keymapd dependency from display/greeter services
- prefix toolchain: relibc headers synced, _RELIBC_STDLIB_H guard unified

Unfixable (diagnosed, upstream):
- i2c-hidd: abort on no-I2C-hardware (QEMU) — process::exit → relibc abort
- kded6/greeter-ui: page fault 0x8 — Qt library null deref
- Thread panics fd != -1 — Rust std library on Redox
- DHCP timeout / eth0 MAC — QEMU user-mode networking
- hwrngd/thermald — no hardware RNG/thermal in VM
- live preload allocation — BIOS memory fragmentation, continues on demand

local/recipes/qt/qtdeclarative/source/tests/auto/qmltest/itemgrabber/CMakeLists.txt

@@ -0,0 +1,21 @@
+# Copyright (C) 2022 The Qt Company Ltd.
+# SPDX-License-Identifier: BSD-3-Clause
+
+# Generated from itemgrabber.pro.
+
+#####################################################################
+## itemgrabber Test:
+#####################################################################
+
+if(NOT QT_BUILD_STANDALONE_TESTS AND NOT QT_BUILDING_QT)
+    cmake_minimum_required(VERSION 3.16)
+    project(itemgrabber LANGUAGES CXX)
+    find_package(Qt6BuildInternals REQUIRED COMPONENTS STANDALONE_TEST)
+endif()
+
+qt_internal_add_test(itemgrabber
+    GUI
+    QMLTEST
+    LIBRARIES
+        Qt::Gui
+)

local/recipes/qt/qtdeclarative/source/tests/auto/qmltest/itemgrabber/tst_itemgrabber.qml

@@ -0,0 +1,161 @@
+// Copyright (C) 2016 Jolla Ltd, author: <gunnar.sletta@jollamobile.com>
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR GPL-3.0-only
+
+import QtQuick 2.4
+import QtTest 1.1
+
+Item {
+    id: root;
+    width: 400
+    height: 400
+
+    TestCase {
+        id: testCase
+        name: "item-grabber"
+        when: imageOnDisk.ready && imageOnDiskSmall.ready
+
+        function test_endresult_disk() {
+            if (Qt.platform.pluginName === "minimal")
+                skip("grabImage does not work on offscreen/minimal platforms");
+
+            var image = grabImage(root);
+
+            // imageOnDisk at (0, 0) - (100x100)
+            compare(imageOnDisk.width, 100);
+            compare(imageOnDisk.height, 100);
+            compare(image.pixel(0, 0), Qt.rgba(1, 0, 0, 1));
+            compare(image.pixel(99, 99), Qt.rgba(0, 0, 1, 1));
+
+            // imageOnDiskSmall at (100, 0) - 50x50
+            compare(imageOnDiskSmall.width, 50);
+            compare(imageOnDiskSmall.height, 50);
+            verify(image.pixel(100, 0) === Qt.rgba(1, 0, 0, 1));
+            verify(image.pixel(149, 49) === Qt.rgba(0, 0, 1, 1));
+        }
+
+        function test_endresult_cache_data() {
+            return [
+                { cache: true, sourceSize: Qt.size(-1, -1), fillMode: Image.Stretch },
+                { cache: true, sourceSize: Qt.size(-1, -1), fillMode: Image.PreserveAspectFit },
+                { cache: true, sourceSize: Qt.size(-1, -1), fillMode: Image.PreserveAspectCrop },
+                { cache: true, sourceSize: Qt.size(10, 10), fillMode: Image.Stretch },
+                { cache: true, sourceSize: Qt.size(10, 10), fillMode: Image.PreserveAspectFit },
+                { cache: true, sourceSize: Qt.size(10, 10), fillMode: Image.PreserveAspectCrop },
+                { cache: false, sourceSize: Qt.size(-1, -1), fillMode: Image.Stretch },
+                { cache: false, sourceSize: Qt.size(-1, -1), fillMode: Image.PreserveAspectFit },
+                { cache: false, sourceSize: Qt.size(-1, -1), fillMode: Image.PreserveAspectCrop },
+                { cache: false, sourceSize: Qt.size(10, 10), fillMode: Image.Stretch },
+                { cache: false, sourceSize: Qt.size(10, 10), fillMode: Image.PreserveAspectFit },
+                { cache: false, sourceSize: Qt.size(10, 10), fillMode: Image.PreserveAspectCrop },
+            ];
+        }
+
+        function test_endresult_cache(data) {
+            if (Qt.platform.pluginName === "minimal")
+                skip("grabImage does not work on offscreen/minimal platforms");
+
+            imageInCache.cache = data.cache;
+            imageInCache.sourceSize = data.sourceSize;
+            imageInCache.fillMode = data.fillMode;
+            imageInCacheSmall.cache = data.cache;
+            imageInCacheSmall.sourceSize = data.sourceSize;
+            imageInCacheSmall.fillMode = data.fillMode;
+
+            box.grabToImage(imageInCache.handleGrab);
+            box.grabToImage(imageInCacheSmall.handleGrab, Qt.size(50, 50));
+
+            tryCompare(imageInCache, "ready", true);
+            tryCompare(imageInCacheSmall, "ready", true);
+
+            var image = grabImage(root);
+
+            // imageInCache at (0, 100) - 100x100
+            compare(imageInCache.width, 100);
+            compare(imageInCache.height, 100);
+            compare(image.pixel(0, 100), Qt.rgba(1, 0, 0, 1));
+            compare(image.pixel(99, 199), Qt.rgba(0, 0, 1, 1));
+
+            // imageInCacheSmall at (100, 100) - 50x50
+            compare(imageInCacheSmall.width, 50);
+            compare(imageInCacheSmall.height, 50);
+            verify(image.pixel(100, 100) === Qt.rgba(1, 0, 0, 1));
+            verify(image.pixel(149, 149) === Qt.rgba(0, 0, 1, 1));
+
+            // After all that has been going on, it should only have been called that one time..
+            compare(imageOnDisk.callCount, 1);
+        }
+
+        onWindowShownChanged: {
+            box.grabToImage(imageOnDisk.handleGrab);
+            box.grabToImage(imageOnDiskSmall.handleGrab, Qt.size(50, 50));
+        }
+
+    }
+
+    Rectangle {
+        id: box
+        width: 100
+        height: 100
+        color: "red";
+
+        visible: false
+
+        Rectangle {
+            anchors.bottom: parent.bottom;
+            anchors.right: parent.right;
+            width: 10
+            height: 10
+            color: "blue";
+        }
+    }
+
+    Image {
+        id: imageOnDisk
+        x: 0
+        y: 0
+        property int callCount: 0;
+        property bool ready: false;
+        function handleGrab(result) {
+            if (!result.saveToFile("image.png"))
+                print("Error: Failed to save image to disk...");
+            source = "image.png";
+            ready = true;
+            ++callCount;
+        }
+    }
+
+    Image {
+        id: imageOnDiskSmall
+        x: 100
+        y: 0
+        property bool ready: false;
+        function handleGrab(result) {
+            if (!result.saveToFile("image_small.png"))
+                print("Error: Failed to save image to disk...");
+            source = "image_small.png";
+            ready = true;
+        }
+    }
+
+    Image {
+        id: imageInCache
+        x: 0
+        y: 100
+        property bool ready: false;
+        function handleGrab(result) {
+            source = result.url;
+            ready = true;
+        }
+    }
+
+    Image {
+        id: imageInCacheSmall
+        x: 100
+        y: 100
+        property bool ready: false;
+        function handleGrab(result) {
+            source = result.url;
+            ready = true;
+        }
+    }
+}