Advance Wayland and KDE package bring-up

Ultraworked with [Sisyphus](https://github.com/code-yeongyu/oh-my-openagent)

Co-authored-by: Sisyphus <clio-agent@sisyphuslabs.ai>

local/recipes/kde/kf6-extra-cmake-modules/source/tests/KDEInstallDirsTest/not_cache_variable/CMakeLists.txt

@@ -0,0 +1,47 @@
+# Test KDEInstallDirs does not crash if a variable like CMAKE_INSTALL_LIBDIR is
+# defined but is not a cache variable.
+cmake_minimum_required(VERSION 2.8)
+
+set(ECM_KDE_MODULE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../../kde-modules)
+set(ECM_MODULE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../../modules)
+set(CMAKE_MODULE_PATH "${ECM_KDE_MODULE_DIR}")
+
+set(KDE_INSTALL_BINDIR "altbin")
+set(CMAKE_INSTALL_DATADIR "altdata")
+set(LIB_INSTALL_DIR "altlib")
+
+include(KDEInstallDirs)
+
+
+include(../var_list.cmake)
+include(../../test_helpers.cmake)
+
+message(STATUS "Checking result of setting KDE_INSTALL_BINDIR")
+assert_var_str_value(KDE_INSTALL_BINDIR "altbin")
+if(should_set_CMAKE_INSTALL_BINDIR)
+    assert_var_str_value(CMAKE_INSTALL_BINDIR "altbin")
+endif()
+if(NOT KDE_INSTALL_DIRS_NO_DEPRECATED)
+    assert_var_str_value(BIN_INSTALL_DIR "altbin")
+endif()
+
+if(should_set_CMAKE_INSTALL_DATADIR)
+    message(STATUS "Checking result of setting CMAKE_INSTALL_DATADIR")
+    assert_var_str_value(KDE_INSTALL_DATADIR "altdata")
+    assert_var_str_value(CMAKE_INSTALL_DATADIR "altdata")
+    if(NOT KDE_INSTALL_DIRS_NO_DEPRECATED)
+        assert_var_str_value(DATA_INSTALL_DIR "altdata")
+    endif()
+endif()
+
+if(NOT KDE_INSTALL_DIRS_NO_DEPRECATED)
+    message(STATUS "Checking result of setting LIB_INSTALL_DIR")
+    assert_var_str_value(KDE_INSTALL_LIBDIR "altlib")
+    if(should_set_CMAKE_INSTALL_LIBDIR)
+        assert_var_str_value(CMAKE_INSTALL_LIBDIR "altlib")
+    endif()
+    assert_var_str_value(LIB_INSTALL_DIR "altlib")
+endif()
+
+add_executable(dummy main.c)
+set_target_properties(dummy PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})

local/recipes/kde/kf6-extra-cmake-modules/source/tests/KDEInstallDirsTest/not_cache_variable/main.c

@@ -0,0 +1,4 @@
+int main()
+{
+   return 0;
+}

local/recipes/kde/kf6-extra-cmake-modules/source/tests/KDEInstallDirsTest/relative_or_absolute/CMakeLists.txt

@@ -0,0 +1,27 @@
+cmake_minimum_required(VERSION 3.5)
+project(KDEInstallDirs.relative_or_absolute)
+
+set(ECM_KDE_MODULE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../../kde-modules)
+set(ECM_MODULE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../../modules)
+set(CMAKE_MODULE_PATH "${ECM_KDE_MODULE_DIR}")
+include(KDEInstallDirs)
+
+include(../var_list.cmake)
+include(../../test_helpers.cmake)
+
+if(APPLE)
+    # The default bundle directory is an absolute path
+    set(BUNDLEDIR_should_be_absolute TRUE)
+endif()
+
+foreach(suffix ${var_suffixes})
+    if(${suffix}_should_be_absolute)
+        assert_var_absolute_path(KDE_INSTALL_${suffix})
+    else()
+        assert_var_relative_path(KDE_INSTALL_${suffix})
+    endif()
+    assert_var_absolute_path(KDE_INSTALL_FULL_${suffix})
+endforeach()
+
+add_executable(dummy main.c)
+set_target_properties(dummy PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})

local/recipes/kde/kf6-extra-cmake-modules/source/tests/KDEInstallDirsTest/relative_or_absolute/main.c

@@ -0,0 +1,4 @@
+int main()
+{
+   return 0;
+}

local/recipes/kde/kf6-extra-cmake-modules/source/tests/KDEInstallDirsTest/var_list.cmake

@@ -0,0 +1,148 @@
+set(var_suffixes
+    APPDIR
+    AUTOSTARTDIR
+    BINDIR
+    CMAKEPACKAGEDIR
+    CONFDIR
+    DATADIR
+    DATADIR_KF
+    DATAROOTDIR
+    DBUSDIR
+    DBUSINTERFACEDIR
+    DBUSSERVICEDIR
+    DBUSSYSTEMSERVICEDIR
+    DESKTOPDIR
+    DOCBUNDLEDIR
+    EXECROOTDIR
+    ICONDIR
+    INCLUDEDIR
+    INCLUDEDIR_KF
+    INFODIR
+    KCFGDIR
+    KCONFUPDATEDIR
+    KNOTIFYRCDIR
+    KXMLGUIDIR
+    LIBDIR
+    LIBEXECDIR
+    LIBEXECDIR_KF
+    LOCALEDIR
+    LOCALSTATEDIR
+    MANDIR
+    MIMEDIR
+    METAINFODIR
+    PLUGINDIR
+    QCHDIR
+    QMLDIR
+    QTPLUGINDIR
+    QTQCHDIR
+    SBINDIR
+    SHAREDSTATEDIR
+    SOUNDDIR
+    SYSCONFDIR
+    SYSTEMDUNITDIR
+    SYSTEMDUSERUNITDIR
+    TEMPLATEDIR
+    WALLPAPERDIR)
+if (QT_MAJOR_VERSION EQUAL "5")
+    list(APPEND var_suffixes
+        DATADIR_KF5
+        INCLUDEDIR_KF5
+        KNOTIFY5RCDIR
+        KXMLGUI5DIR
+        KSERVICES5DIR
+        KSERVICETYPES5DIR
+        LIBEXECDIR_KF5
+        QTQUICKIMPORTSDIR
+        KSERVICESDIR
+        KSERVICETYPESDIR
+    )
+endif()
+if(APPLE)
+    list(APPEND var_suffixes BUNDLEDIR)
+endif()
+
+set(compat_APPDIR XDG_APPS_INSTALL_DIR)
+set(compat_AUTOSTARTDIR AUTOSTART_INSTALL_DIR)
+set(compat_BINDIR BIN_INSTALL_DIR)
+set(compat_CMAKEPACKAGEDIR CMAKECONFIG_INSTALL_PREFIX)
+set(compat_CONFDIR CONFIG_INSTALL_DIR)
+set(compat_DATADIR DATA_INSTALL_DIR)
+set(compat_DATADIR_KF5 KF5_DATA_INSTALL_DIR)
+set(compat_DATAROOTDIR SHARE_INSTALL_PREFIX)
+set(compat_DBUSINTERFACEDIR DBUS_INTERFACES_INSTALL_DIR)
+set(compat_DBUSSERVICEDIR DBUS_SERVICES_INSTALL_DIR)
+set(compat_DBUSSYSTEMSERVICEDIR DBUS_SYSTEM_SERVICES_INSTALL_DIR)
+set(compat_DESKTOPDIR XDG_DIRECTORY_INSTALL_DIR)
+set(compat_DOCBUNDLEDIR HTML_INSTALL_DIR)
+set(compat_EXECROOTDIR EXEC_INSTALL_PREFIX)
+set(compat_ICONDIR ICON_INSTALL_DIR)
+set(compat_INCLUDEDIR INCLUDE_INSTALL_DIR)
+set(compat_INCLUDEDIR_KF5 KF5_INCLUDE_INSTALL_DIR)
+set(compat_KCFGDIR KCFG_INSTALL_DIR)
+set(compat_KCONFUPDATEDIR KCONF_UPDATE_INSTALL_DIR)
+set(compat_KNOTIFY5RCDIR KNOTIFYRC_INSTALL_DIR)
+set(compat_KXMLGUI5DIR KXMLGUI_INSTALL_DIR)
+set(compat_KSERVICES5DIR SERVICES_INSTALL_DIR)
+set(compat_KSERVICETYPES5DIR SERVICETYPES_INSTALL_DIR)
+set(compat_LIBDIR LIB_INSTALL_DIR)
+set(compat_LIBEXECDIR LIBEXEC_INSTALL_DIR)
+set(compat_LIBEXECDIR_KF5 KF5_LIBEXEC_INSTALL_DIR)
+set(compat_LOCALEDIR LOCALE_INSTALL_DIR)
+set(compat_MANDIR MAN_INSTALL_DIR)
+set(compat_MIMEDIR XDG_MIME_INSTALL_DIR)
+set(compat_PLUGINDIR PLUGIN_INSTALL_DIR)
+set(compat_QMLDIR QML_INSTALL_DIR)
+set(compat_QTPLUGINDIR QT_PLUGIN_INSTALL_DIR)
+set(compat_QTQUICKIMPORTSDIR IMPORTS_INSTALL_DIR)
+set(compat_SBINDIR SBIN_INSTALL_DIR)
+set(compat_SOUNDDIR SOUND_INSTALL_DIR)
+set(compat_SYSCONFDIR SYSCONF_INSTALL_DIR)
+set(compat_SYSTEM_UNIT_INSTALL_DIR)
+set(compat_SYSTEM_USER_UNIT_INSTALL_DIR)
+set(compat_TEMPLATEDIR TEMPLATES_INSTALL_DIR)
+set(compat_WALLPAPERDIR WALLPAPER_INSTALL_DIR)
+if(APPLE)
+    set(compat_BUNDLEDIR BUNDLE_INSTALL_DIR)
+endif()
+
+set(_gnu_install_dirs_suffixes
+    BINDIR
+    SBINDIR
+    LIBEXECDIR
+    SYSCONFDIR
+    SHAREDSTATEDIR
+    LOCALSTATEDIR
+    LIBDIR
+    INCLUDEDIR
+    OLDINCLUDEDIR
+    DATAROOTDIR
+    DATADIR
+    INFODIR
+    LOCALEDIR
+    MANDIR
+    DOCDIR)
+
+if(KDE_INSTALL_DIRS_NO_CMAKE_VARIABLES)
+    foreach(suffix ${var_suffixes})
+        set(should_set_CMAKE_INSTALL_${suffix} FALSE)
+    endforeach()
+elseif(KDE_INSTALL_DIRS_NO_DEPRECATED)
+    foreach(suffix ${var_suffixes})
+        set(should_set_CMAKE_INSTALL_${suffix} FALSE)
+    endforeach()
+    foreach(suffix ${_gnu_install_dirs_suffixes})
+        set(should_set_CMAKE_INSTALL_${suffix} TRUE)
+    endforeach()
+else()
+    foreach(suffix ${var_suffixes})
+        set(should_set_CMAKE_INSTALL_${suffix} TRUE)
+    endforeach()
+endif()
+
+# newly added version-less vars in 5 do also not set the legacy variables
+foreach(suffix DATADIR_KF INCLUDEDIR_KF KNOTIFYRCDIR KXMLGUIDIR KSERVICESDIR KSERVICETYPESDIR LIBEXECDIR_KF)
+    set(should_set_CMAKE_INSTALL_${suffix} FALSE)
+endforeach()
+
+unset(_gnu_install_dirs_suffixes)
+

local/recipes/kde/kf6-extra-cmake-modules/source/tests/KDEInstallDirsTest/vars_in_sync/CMakeLists.txt

@@ -0,0 +1,41 @@
+cmake_minimum_required(VERSION 3.5)
+project(KDEInstallDirs.vars_in_sync)
+
+set(ECM_KDE_MODULE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../../kde-modules)
+set(ECM_MODULE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../../modules)
+set(CMAKE_MODULE_PATH "${ECM_KDE_MODULE_DIR}")
+include(KDEInstallDirs)
+
+include(../var_list.cmake)
+include(../../test_helpers.cmake)
+
+foreach(suffix ${var_suffixes})
+    assert_var_defined(KDE_INSTALL_${suffix})
+    if(DEFINED ${suffix}_expected_value)
+        assert_vars_strequal(KDE_INSTALL_${suffix} ${suffix}_expected_value)
+    endif()
+    assert_var_defined(KDE_INSTALL_FULL_${suffix})
+
+    if(should_set_CMAKE_INSTALL_${suffix})
+        assert_vars_strequal(CMAKE_INSTALL_${suffix} KDE_INSTALL_${suffix})
+        assert_vars_strequal(CMAKE_INSTALL_FULL_${suffix} KDE_INSTALL_FULL_${suffix})
+    endif()
+
+    if(NOT KDE_INSTALL_DIRS_NO_DEPRECATED AND DEFINED compat_${suffix})
+        assert_vars_strequal(${compat_${suffix}} KDE_INSTALL_${suffix})
+    endif()
+endforeach()
+
+assert_var_defined(KF_INSTALL_TARGETS_DEFAULT_ARGS)
+if (QT_MAJOR_VERSION EQUAL "5")
+    assert_var_defined(KF5_INSTALL_TARGETS_DEFAULT_ARGS)
+endif()
+assert_var_defined(KDE_INSTALL_TARGETS_DEFAULT_ARGS)
+if(NOT KDE_INSTALL_DIRS_NO_CMAKE_VARIABLES AND
+   NOT KDE_INSTALL_DIRS_NO_DEPRECATED)
+    assert_vars_strequal(INSTALL_TARGETS_DEFAULT_ARGS
+                         KDE_INSTALL_TARGETS_DEFAULT_ARGS)
+endif()
+
+add_executable(dummy main.c)
+set_target_properties(dummy PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})

local/recipes/kde/kf6-extra-cmake-modules/source/tests/KDEInstallDirsTest/vars_in_sync/main.c

@@ -0,0 +1,4 @@
+int main()
+{
+   return 0;
+}